view src/net/kryshen/indyvon/layers.clj @ 78:4c0f2af742ba

Added timestamp to the layer context.
author Mikhail Kryshen <mikhail@kryshen.net>
date Wed, 01 Sep 2010 21:13:55 +0400
parents 1ca7872b889b
children 880ae8e03408
line source
1 ;;
2 ;; Copyright 2010 Mikhail Kryshen <mikhail@kryshen.net>
3 ;;
4 ;; This file is part of Indyvon.
5 ;;
6 ;; Indyvon is free software: you can redistribute it and/or modify it
7 ;; under the terms of the GNU Lesser General Public License version 3
8 ;; only, as published by the Free Software Foundation.
9 ;;
10 ;; Indyvon is distributed in the hope that it will be useful, but
11 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 ;; Lesser General Public License for more details.
14 ;;
15 ;; You should have received a copy of the GNU Lesser General Public
16 ;; License along with Indyvon. If not, see
17 ;; <http://www.gnu.org/licenses/>.
18 ;;
20 (ns net.kryshen.indyvon.layers
21 "Implementations of Layer protocol."
22 (:use
23 (net.kryshen.indyvon core async))
24 (:import
25 (net.kryshen.indyvon.core Size Location)
26 (java.lang.ref SoftReference)
27 (java.awt Font Cursor Image Toolkit)
28 (java.awt.image ImageObserver)
29 (java.awt.font FontRenderContext TextLayout)))
31 ;; Define as macro to avoid unnecessary calculation of inner and outer
32 ;; sizes in the first case.
33 (defmacro align-xy [inner outer align first center last]
34 `(case ~align
35 ~first 0
36 ~center (/ (- ~outer ~inner) 2)
37 ~last (- ~outer ~inner)))
39 (defmacro align-x [inner outer align]
40 `(align-xy ~inner ~outer ~align :left :center :right))
42 (defmacro align-y [inner outer align]
43 `(align-xy ~inner ~outer ~align :top :center :bottom))
45 (defmacro decorate-layer
46 "Decorate Layer and Anchored replacing render! implementation."
47 [layer & render-tail]
48 `(reify
49 Layer
50 (render! ~@render-tail)
51 (layer-size [t#] (layer-size ~layer))
52 Anchored
53 (anchor [t# xa# ya#] (anchor ~layer xa# ya#))))
55 (defn padding
56 "Decorates layer adding padding."
57 ([content pad]
58 (padding content pad pad pad pad))
59 ([content top left bottom right]
60 (if (== 0 top left bottom right)
61 content
62 (reify
63 Layer
64 (render! [l]
65 (draw! content
66 left top
67 (- *width* left right)
68 (- *height* top bottom)))
69 (layer-size [l]
70 (let [s (layer-size content)]
71 (Size. (+ (:width s) left right)
72 (+ (:height s) top bottom))))))))
74 (defn border
75 "Decorate layer with a border."
76 ([content]
77 (border content 1))
78 ([content width]
79 (border content width 0))
80 ([content width gap]
81 (let [layer (padding content (+ width gap))]
82 (decorate-layer layer [_]
83 (with-color :border-color
84 (doseq [i (range 0 width)]
85 (.drawRect *graphics* i i
86 (- *width* 1 i i)
87 (- *height* 1 i i))))
88 (render! layer)))))
90 (defn panel
91 "Opaque layer using theme's alt-back-color."
92 ([content]
93 (panel content 0))
94 ([content gap]
95 (let [layer (padding content gap)]
96 (decorate-layer layer [_]
97 (with-color :alt-back-color
98 (.fillRect *graphics* 0 0 *width* *height*))
99 (render! layer)))))
101 (defn hbox
102 "Creates layer that draws the specified content layers placing them
103 horizontally."
104 [& contents]
105 (reify
106 Layer
107 (render! [_]
108 ;; TODO: distribute space proportionally.
109 (let [w (/ *width* (count contents))]
110 (doseq [[i c] (map-indexed vector contents)]
111 (draw! c (* i w) 0 w *height*))))
112 (layer-size [_]
113 (reduce #(Size. (+ (:width %1) (:width %2))
114 (max (:height %1) (:height %2)))
115 (Size. 0 0)
116 (map layer-size contents)))))
118 (defn- re-split [^java.util.regex.Pattern re s]
119 (seq (.split re s)))
121 (def text-layout-cache (atom {}))
123 (defn- get-text-layout
124 [^String line ^Font font ^FontRenderContext font-context]
125 (let [key [line font font-context]]
126 (or (if-let [^SoftReference softref (@text-layout-cache key)]
127 (.get softref)
128 (do (swap! text-layout-cache dissoc key)
129 false))
130 (let [layout (TextLayout. line font font-context)]
131 ;;(println "text-layout-cache miss" line)
132 (swap! text-layout-cache assoc key (SoftReference. layout))
133 layout))))
135 (defn- layout-text
136 [lines ^Font font ^FontRenderContext font-context]
137 (map #(get-text-layout % font font-context) lines))
138 ;;(map #(TextLayout. ^String % font font-context) lines))
140 (defn- text-width [layouts]
141 (reduce (fn [w ^TextLayout tl] (max w (.getAdvance tl))) 0 layouts))
143 (defn- text-height [layouts]
144 (reduce (fn [w ^TextLayout tl]
145 (+ w (.getAscent tl)
146 (.getDescent tl)
147 (.getLeading tl)))
148 0 layouts))
150 (defn label
151 "Creates a layer to display multiline text."
152 ([text]
153 (label text :left :top))
154 ([text h-align v-align]
155 (let [lines (re-split #"\r\n|\n|\r|\u0085|\u2028|\u2029" text)]
156 (reify Layer
157 (render! [layer]
158 (let [w *width*
159 h *height*
160 font (.getFont *graphics*)
161 layouts (layout-text lines font *font-context*)
162 y (align-y (text-height layouts) h v-align)]
163 (loop [layouts layouts, y y]
164 (when-first [^TextLayout layout layouts]
165 (let [ascent (.getAscent layout)
166 lh (+ ascent (.getDescent layout) (.getLeading layout))
167 x (align-x (.getAdvance layout) w h-align)]
168 (.draw layout *graphics* x (+ y ascent))
169 (recur (next layouts) (+ y lh)))))))
170 (layer-size [layer]
171 (let [layouts (layout-text lines (:font *theme*) *font-context*)
172 width (text-width layouts)
173 height (text-height layouts)]
174 (Size. width height)))))))
176 (defn- ^ImageObserver image-observer [layer]
177 (reify
178 ImageObserver
179 (imageUpdate [this img infoflags x y width height]
180 (update layer)
181 (zero? (bit-and infoflags
182 (bit-or ImageObserver/ALLBITS
183 ImageObserver/ABORT))))))
185 (defn image-layer
186 [image-or-uri]
187 (let [^Image image (if (isa? image-or-uri Image)
188 image-or-uri
189 (.getImage (Toolkit/getDefaultToolkit)
190 ^java.net.URL image-or-uri))]
191 (.prepareImage (Toolkit/getDefaultToolkit) image -1 -1 nil)
192 (reify
193 Layer
194 (render! [layer]
195 (repaint-on-update layer)
196 (.drawImage *graphics* image 0 0 (image-observer layer)))
197 (layer-size [layer]
198 (let [observer (image-observer layer)
199 width (.getWidth image observer)
200 height (.getHeight image observer)
201 width (if (pos? width) width 1)
202 height (if (pos? height) height 1)]
203 (Size. width height))))))
205 (defn miniature
206 "Creates layer that asynchronously renders view of the content
207 scaled to the specified size."
208 [content width height]
209 (async-layer
210 (reify
211 Layer
212 (render! [this]
213 (let [size (layer-size content)
214 sx (/ width (:width size))
215 sy (/ height (:height size))]
216 (.scale *graphics* sx sy)
217 (draw! content 0 0 (:width size) (:height size))))
218 (layer-size [this]
219 (Size. width height)))
220 width height))
222 (defrecord Viewport [content h-align v-align
223 ;; state (refs)
224 x y fix-x fix-y last-width last-height]
225 Layer
226 (render! [layer]
227 (repaint-on-update layer)
228 (with-handlers layer
229 (let [anchor (anchor content h-align v-align)]
230 (dosync
231 (alter x + (align-x *width* @last-width h-align))
232 (alter y + (align-y *height* @last-height v-align))
233 (ref-set last-width *width*)
234 (ref-set last-height *height*))
235 ;; TODO: notify observers when size changes.
236 (draw! content (- 0 @x (:x anchor)) (- 0 @y (:y anchor))))
237 (:mouse-pressed e
238 (dosync
239 (ref-set fix-x (:x-on-screen e))
240 (ref-set fix-y (:y-on-screen e)))
241 (when *target*
242 (->> Cursor/MOVE_CURSOR Cursor. (.setCursor *target*))))
243 (:mouse-released e
244 (when *target*
245 (->> Cursor/DEFAULT_CURSOR Cursor. (.setCursor *target*))))
246 (:mouse-dragged e
247 (dosync
248 (alter x + (- @fix-x (:x-on-screen e)))
249 (alter y + (- @fix-y (:y-on-screen e)))
250 (ref-set fix-x (:x-on-screen e))
251 (ref-set fix-y (:y-on-screen e)))
252 (update layer))))
253 (layer-size [layer]
254 (layer-size content)))
256 (defn viewport
257 "Creates scrollable viewport layer."
258 ([content] (viewport content :left :top))
259 ([content h-align v-align]
260 (Viewport. content h-align v-align
261 (ref 0) (ref 0) ; x y
262 (ref 0) (ref 0) ; fix-x fix-y
263 (ref 0) (ref 0)))) ; last-width last-height
265 (defn- viewport-visible-bounds
266 [viewport]
267 (dosync
268 [@(:x viewport) @(:y viewport)
269 @(:last-width viewport) @(:last-height viewport)]))
271 (defn viewport-miniature
272 "Creates miniature view of the viewport's contents."
273 [viewport width height]
274 (miniature
275 (decorate-layer (:content viewport) [_]
276 (repaint-on-update viewport)
277 (let [[x y w h] (viewport-visible-bounds viewport)]
278 (with-color :alt-back-color
279 (.fillRect *graphics* 0 0 *width* *height*))
280 (with-color :back-color
281 (.fillRect *graphics* x y w h))
282 (draw! (:content viewport))
283 (with-color :border-color
284 (.drawRect *graphics* x y w h))))
285 width height))
287 (defn- fps-label [text]
288 (padding (label text :right :bottom) 5))
290 (defn fps-layer
291 "Creates layer that draws content and displays
292 the frames per seconds rate."
293 [content]
294 (let [update-interval 2E8 ; 0.2 s in nanoseconds
295 frames (ref 0)
296 prev-time (ref nil)
297 display (ref (fps-label "fps n/a"))]
298 (decorate-layer content [_]
299 (draw! content)
300 (draw!
301 (dosync
302 (alter frames inc)
303 (if @prev-time
304 (let [elapsed (- *time* @prev-time)]
305 (when (> elapsed update-interval)
306 (let [fps (/ @frames (/ elapsed 1E9))]
307 (ref-set display (fps-label (format "%.1f" fps)))
308 (ref-set frames 0)
309 (ref-set prev-time *time*))))
310 (ref-set prev-time *time*))
311 @display)))))
313 ;;
314 ;; Layer context decorators.
315 ;;
317 (defmacro handler [layer & handlers]
318 "Decorate layer to handle events."
319 `(let [layer# ~layer]
320 (decorate-layer layer# [t#]
321 (with-handlers t#
322 (render! layer#)
323 ~@handlers))))
325 (defn theme [layer & map-or-keyvals]
326 (let [theme (if (== (count map-or-keyvals) 1)
327 map-or-keyvals
328 (apply array-map map-or-keyvals))]
329 (reify
330 Layer
331 (render! [t]
332 (with-theme theme
333 (render! layer)))
334 (layer-size [t]
335 (with-theme theme
336 (layer-size layer)))
337 Anchored
338 (anchor [t xa ya]
339 (with-theme theme
340 (anchor layer xa ya))))))