view src/net/kryshen/indyvon/layers.clj @ 124:6dae98ac9af4

Better way to draw borders.
author Mikhail Kryshen <mikhail@kryshen.net>
date Fri, 06 Apr 2012 20:49:21 +0400
parents 87ebc46cc66d
children 24c7935a8f06
line source
1 ;;
2 ;; Copyright 2010, 2011 Mikhail Kryshen <mikhail@kryshen.net>
3 ;;
4 ;; This file is part of Indyvon.
5 ;;
6 ;; Indyvon is free software: you can redistribute it and/or modify it
7 ;; under the terms of the GNU Lesser General Public License version 3
8 ;; only, as published by the Free Software Foundation.
9 ;;
10 ;; Indyvon is distributed in the hope that it will be useful, but
11 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 ;; Lesser General Public License for more details.
14 ;;
15 ;; You should have received a copy of the GNU Lesser General Public
16 ;; License along with Indyvon. If not, see
17 ;; <http://www.gnu.org/licenses/>.
18 ;;
20 (ns net.kryshen.indyvon.layers
21 "Implementations of Layer protocol."
22 (:use
23 (net.kryshen.indyvon core async))
24 (:import
25 (java.lang.ref SoftReference)
26 (java.awt Font Cursor Image Toolkit Point)
27 java.awt.image.ImageObserver
28 (java.awt.geom AffineTransform Rectangle2D$Double Point2D$Double
29 Path2D Path2D$Double)
30 (java.awt.font FontRenderContext TextLayout)
31 java.util.concurrent.TimeUnit
32 (com.google.common.cache Cache CacheBuilder CacheLoader)))
34 ;; Define as macro to avoid unnecessary calculation of inner and outer
35 ;; sizes in the first case.
36 (defmacro align-xy [inner outer align first center last]
37 `(case ~align
38 ~first 0
39 ~center (/ (- ~outer ~inner) 2)
40 ~last (- ~outer ~inner)))
42 (defmacro align-x [inner outer align]
43 `(align-xy ~inner ~outer ~align :left :center :right))
45 (defmacro align-y [inner outer align]
46 `(align-xy ~inner ~outer ~align :top :center :bottom))
48 (defmacro decorate-layer
49 "Decorate Layer replacing render! implementation."
50 [layer & render-tail]
51 `(let [layer# ~layer]
52 (reify
53 Layer
54 (render! ~@render-tail)
55 (geometry [t#] (geometry layer#)))))
57 (defrecord Empty []
58 Layer
59 (render! [_])
60 (geometry [_]
61 (->Size 0 0)))
63 (def empty-layer (->Empty))
65 (defn padding
66 "Decorates layer adding padding."
67 ([content pad]
68 (padding content pad pad pad pad))
69 ([content top left bottom right]
70 (if (== 0 top left bottom right)
71 content
72 (reify
73 Layer
74 (render! [l]
75 (draw! content
76 left top
77 (- *width* left right)
78 (- *height* top bottom)
79 false))
80 (geometry [l]
81 (->NestedGeometry (geometry content) top left bottom right))))))
83 (defn border
84 "Decorate layer with a border."
85 ([content]
86 (border content 1))
87 ([content thikness]
88 (border content thikness 0))
89 ([content thikness gap]
90 (let [layer (padding content (+ thikness gap))
91 t (double thikness)]
92 (decorate-layer layer [_]
93 (with-color :border-color
94 (let [w (double *width*)
95 h (double *height*)
96 outer (Rectangle2D$Double. 0.0 0.0 w h)
97 inner (Rectangle2D$Double. t t (- w t t) (- h t t))]
98 (.fill *graphics*
99 (doto (Path2D$Double. Path2D/WIND_EVEN_ODD)
100 (.append outer false)
101 (.append inner false)))))
102 (render! layer)))))
104 ;; TODO: opacity and blur.
105 (defn shadow
106 "Add shadow to content layer."
107 ([content]
108 (shadow content 1 1))
109 ([content x-offset y-offset]
110 (let [x (if (neg? x-offset) (- x-offset) 0)
111 y (if (neg? y-offset) (- y-offset) 0)
112 abs-x (if (neg? x-offset) (- x-offset) x-offset)
113 abs-y (if (neg? y-offset) (- y-offset) y-offset)
114 shadow-x (+ x-offset x)
115 shadow-y (+ y-offset y)]
116 (reify
117 Layer
118 (render! [_]
119 (let [w (- *width* abs-x)
120 h (- *height* abs-y)]
121 (with-color :shadow-color
122 (.fillRect *graphics* shadow-x shadow-y w h))
123 (draw! content x y w h)))
124 (geometry [_]
125 (->NestedGeometry (geometry content)
126 y x shadow-y shadow-x))))))
128 (defn panel
129 "Opaque layer using theme's alt-back-color."
130 ([content]
131 (panel content 0))
132 ([content gap]
133 (let [layer (padding content gap)]
134 (decorate-layer layer [_]
135 (with-color :alt-back-color
136 (.fillRect *graphics* 0 0 *width* *height*))
137 (render! layer)))))
139 (defn hbox
140 "Creates layer that draws the specified content layers placing them
141 horizontally."
142 [& contents]
143 (reify
144 Layer
145 (render! [_]
146 (let [widths (map #(width (geometry %)) contents)
147 xs (cons 0 (reductions + widths))
148 widths-sum (last xs)
149 scale (/ *width* widths-sum)]
150 (doseq [[c w x] (map vector contents widths xs)]
151 (draw! c x 0 w *height*))))
152 (geometry [_]
153 (reduce #(->Size (+ (width %1) (width %2))
154 (max (height %1) (height %2)))
155 (->Size 0 0)
156 (map geometry contents)))))
158 (defn vbox
159 "Creates layer that draws the specified content layers placing them
160 vertically."
161 [& contents]
162 (reify
163 Layer
164 (render! [_]
165 (let [heights (map #(height (geometry %)) contents)
166 ys (cons 0 (reductions + heights))
167 heights-sum (last ys)
168 scale (/ *height* heights-sum)]
169 (doseq [[c h y] (map vector contents heights ys)]
170 (draw! c 0 y *width* h))))
171 (geometry [_]
172 (reduce #(->Size (max (width %1) (width %2))
173 (+ (height %1) (height %2)))
174 (->Size 0 0)
175 (map geometry contents)))))
177 (defn- re-split [^java.util.regex.Pattern re s]
178 (seq (.split re s)))
180 (def ^:private ^Cache text-layout-cache
181 (-> (CacheBuilder/newBuilder)
182 (.softValues)
183 (.expireAfterAccess (long 1) TimeUnit/SECONDS)
184 (.build
185 (proxy [CacheLoader] []
186 (load [[^String s ^Font f ^FontRenderContext frc]]
187 (TextLayout. s f frc))))))
189 (defn- get-text-layout [line font font-context]
190 (.get text-layout-cache [line font font-context]))
192 (defn- layout-text
193 [lines ^Font font ^FontRenderContext font-context]
194 (map #(get-text-layout % font font-context) lines))
196 (defn- text-width [layouts]
197 (reduce (fn [w ^TextLayout tl] (max w (.getAdvance tl))) 0 layouts))
199 (defn- text-height [layouts]
200 (reduce (fn [w ^TextLayout tl]
201 (+ w (.getAscent tl)
202 (.getDescent tl)
203 (.getLeading tl)))
204 0 layouts))
206 (defn label
207 "Creates a layer to display multiline text."
208 ([text]
209 (label text :left :top))
210 ([text h-align v-align]
211 (let [lines (re-split #"\r\n|\n|\r|\u0085|\u2028|\u2029" (str text))]
212 (reify Layer
213 (render! [layer]
214 (let [w *width*
215 h *height*
216 font (.getFont *graphics*)
217 layouts (layout-text lines font (font-context))
218 y (align-y (text-height layouts) h v-align)]
219 (loop [layouts layouts, y y]
220 (when-first [^TextLayout layout layouts]
221 (let [ascent (.getAscent layout)
222 lh (+ ascent (.getDescent layout) (.getLeading layout))
223 x (align-x (.getAdvance layout) w h-align)]
224 (.draw layout *graphics* x (+ y ascent))
225 (recur (next layouts) (+ y lh)))))))
226 (geometry [layer]
227 (let [layouts (layout-text lines (:font *theme*) (font-context))
228 w (text-width layouts)
229 h (text-height layouts)]
230 (->Size w h)))))))
232 (defn- ^ImageObserver image-observer [layer]
233 (reify
234 ImageObserver
235 (imageUpdate [this img infoflags x y width height]
236 (update layer)
237 (zero? (bit-and infoflags
238 (bit-or ImageObserver/ALLBITS
239 ImageObserver/ABORT))))))
241 (defn image-layer
242 [image-or-uri]
243 (let [^Image image (if (instance? Image image-or-uri)
244 image-or-uri
245 (.getImage (Toolkit/getDefaultToolkit)
246 ^java.net.URL image-or-uri))]
247 (.prepareImage (Toolkit/getDefaultToolkit) image -1 -1 nil)
248 (reify
249 Layer
250 (render! [layer]
251 (repaint-on-update layer)
252 (.drawImage *graphics* image 0 0 (image-observer layer)))
253 (geometry [layer]
254 (let [observer (image-observer layer)
255 width (.getWidth image observer)
256 height (.getHeight image observer)
257 width (if (pos? width) width 1)
258 height (if (pos? height) height 1)]
259 (->Size width height))))))
261 (def ^:dynamic *miniature-thread-priority* 2)
263 (defn- scaling
264 [width height max-width max-height]
265 (min (/ max-width width)
266 (/ max-height height)))
268 (defn miniature
269 "Creates layer that asynchronously renders view of the content
270 scaled to the specified size."
271 [content mw mh]
272 (async-layer
273 (reify
274 Layer
275 (render! [this]
276 (let [geom (geometry content)
277 cw (width geom)
278 ch (height geom)
279 s (scaling cw ch mw mh)]
280 (.scale *graphics* s s)
281 (draw! content
282 (align-x cw (/ mw s) :center)
283 (align-y ch (/ mh s) :center)
284 cw ch)))
285 (geometry [_]
286 (->Size mw mh)))
287 mw mh *miniature-thread-priority*))
289 ;;(defn- translate [^AffineTransform transform ^double x ^double y]
290 ;; (doto ^AffineTransform (.clone transform)
291 ;; (.translate x y)))
293 (defn- scale [^AffineTransform transform ^double sx ^double sy]
294 (doto ^AffineTransform (.clone transform)
295 (.scale sx sy)))
297 (defn- pre-translate [^AffineTransform transform ^double x ^double y]
298 (if (== 0.0 x y)
299 transform
300 (doto (AffineTransform/getTranslateInstance x y)
301 (.concatenate transform))))
303 (def ^:dynamic *viewport-scaling-step* (double 3/4))
304 (def ^:dynamic *viewport-min-scale* 1E-6)
305 (def ^:dynamic *viewport-max-scale* 1E6)
307 (defrecord Viewport [content h-align v-align
308 ;; State (refs)
309 transform
310 fix-x fix-y
311 last-width last-height
312 last-anchor-x last-anchor-y]
313 Layer
314 (render! [layer]
315 (repaint-on-update layer)
316 (with-handlers layer
317 (let [geom (geometry content)
318 cw (width geom)
319 ch (height geom)
320 ax (anchor-x geom h-align cw)
321 ay (anchor-y geom v-align ch)]
322 (dosync
323 (let [ax1 (align-x @last-width *width* h-align)
324 ay1 (align-y @last-height *height* v-align)
325 ax2 (- @last-anchor-x ax)
326 ay2 (- @last-anchor-y ay)]
327 (if-not (and (zero? ax1) (zero? ay1) (zero? ax2) (zero? ay2))
328 (ref-set transform
329 (doto (AffineTransform/getTranslateInstance ax1 ay1)
330 (.concatenate @transform)
331 (.translate ax2 ay2)))))
332 (ref-set last-width *width*)
333 (ref-set last-height *height*)
334 (ref-set last-anchor-x ax)
335 (ref-set last-anchor-y ay))
336 ;; TODO: notify observers when size changes.
337 (with-transform @transform
338 (draw! content 0 0 cw ch false)))
339 (:mouse-pressed e
340 (dosync
341 (ref-set fix-x (:x-on-screen e))
342 (ref-set fix-y (:y-on-screen e)))
343 (set-cursor! (Cursor. Cursor/MOVE_CURSOR)))
344 (:mouse-released e
345 (set-cursor! (Cursor. Cursor/DEFAULT_CURSOR)))
346 (:mouse-dragged e
347 (dosync
348 (alter transform pre-translate
349 (- (:x-on-screen e) @fix-x)
350 (- (:y-on-screen e) @fix-y))
351 (ref-set fix-x (:x-on-screen e))
352 (ref-set fix-y (:y-on-screen e)))
353 (update layer))
354 (:mouse-wheel e
355 (dosync
356 (let [s (Math/pow *viewport-scaling-step* (:wheel-rotation e))
357 x (- (:x e) (* (:x e) s))
358 y (- (:y e) (* (:y e) s))
359 scaled (doto (AffineTransform/getTranslateInstance x y)
360 (.scale s s)
361 (.concatenate @transform))
362 sx (.getScaleX scaled)
363 sy (.getScaleY scaled)]
364 (if (<= *viewport-min-scale*
365 (min sx sy)
366 (max sx sy)
367 *viewport-max-scale*)
368 (ref-set transform scaled))))
369 (update layer))))
370 (geometry [_]
371 (geometry content)))
373 (defn viewport
374 "Creates scrollable viewport layer."
375 ([content]
376 (viewport content :left :top))
377 ([content h-align v-align]
378 (Viewport. content h-align v-align
379 (ref (AffineTransform.)) ; transform
380 (ref 0) (ref 0) ; fix-x fix-y
381 (ref 0) (ref 0) ; last-width last-height
382 (ref 0) (ref 0)))) ; last-anchor-x last-anchor-y
384 (defn reset-viewport [viewport]
385 (dosync
386 (ref-set (:last-width viewport) 0)
387 (ref-set (:last-height viewport) 0)
388 (ref-set (:last-anchor-x viewport) 0)
389 (ref-set (:last-anchor-y viewport) 0)
390 (ref-set (:transform viewport) (AffineTransform.)))
391 (update viewport))
393 (defn viewport-miniature
394 "Creates miniature view of the viewport's contents."
395 [viewport m-width m-height]
396 (let [miniature (miniature (:content viewport) m-width m-height)]
397 (decorate-layer miniature [l]
398 (repaint-on-update viewport)
399 (let [geom (geometry (:content viewport))
400 s (scaling (width geom) (height geom) m-width m-height)
401 [vp-tr w h] (dosync
402 [@(:transform viewport)
403 @(:last-width viewport)
404 @(:last-height viewport)])
405 vp-inverse (.createInverse ^AffineTransform vp-tr)
406 ox (align-x (width geom) (/ m-width s) :center)
407 oy (align-y (height geom) (/ m-height s) :center)
408 transform (doto (AffineTransform.)
409 (.scale s s)
410 (.translate ox oy)
411 (.concatenate vp-inverse))
412 move-vp (fn [x y]
413 (dosync
414 (let [x (- (/ x s) ox)
415 y (- (/ y s) oy)
416 [x y] (transform-point @(:transform viewport)
417 x y)
418 x (- x (/ @(:last-width viewport) 2))
419 y (- y (/ @(:last-height viewport) 2))]
420 (alter (:transform viewport)
421 pre-translate (- x) (- y))))
422 (update viewport))]
423 (with-color :alt-back-color
424 (.fillRect *graphics* 0 0 *width* *height*))
425 (with-transform transform
426 (with-color :back-color
427 (.fillRect *graphics* 0 0 w h)))
428 (with-handlers l
429 (draw! miniature)
430 (:mouse-pressed e (move-vp (:x e) (:y e)))
431 (:mouse-dragged e (move-vp (:x e) (:y e))))
432 (with-transform transform
433 (with-color :border-color
434 (.drawRect *graphics* 0 0 w h)))))))
436 (defn ref-layer
437 [layer-ref]
438 (let [l (reify
439 Layer
440 (render! [l]
441 (repaint-on-update l)
442 (if-let [layer @layer-ref]
443 (render! layer)))
444 (geometry [_]
445 (if-let [layer @layer-ref]
446 (geometry layer)
447 (->Size 1 1))))]
448 (add-watch layer-ref l (fn [_ _ _ _] (update l)))
449 l))
451 ;;
452 ;; Layer context decorators.
453 ;;
455 (defmacro handler [layer & handlers]
456 "Decorate layer to handle events."
457 `(let [layer# ~layer]
458 (decorate-layer layer# [t#]
459 (with-handlers t#
460 (render! layer#)
461 ~@handlers))))
463 (defn themed [layer & map-or-keyvals]
464 (let [theme (if (== (count map-or-keyvals) 1)
465 (first map-or-keyvals)
466 (apply array-map map-or-keyvals))]
467 (reify
468 Layer
469 (render! [_]
470 (with-theme theme
471 (render! layer)))
472 (geometry [_]
473 (with-theme theme
474 (geometry layer))))))
476 (defn hinted [layer & map-or-keyvals]
477 (let [hints (if (== (count map-or-keyvals) 1)
478 (first map-or-keyvals)
479 (apply array-map map-or-keyvals))]
480 (decorate-layer layer [_]
481 (with-hints* hints render! layer))))
483 ;;
484 ;; Measuring time
485 ;;
487 (def ^:dynamic *interval*)
489 (defn interval-layer
490 "Creates layer that measures time between repaints ant draws it's
491 content with the *interval* var bound to the measured time."
492 [content]
493 (let [last-time (atom nil)]
494 (decorate-layer content [_]
495 (compare-and-set! last-time nil *time*)
496 (let [lt @last-time]
497 (binding [*interval* (if (compare-and-set! last-time lt *time*)
498 (- *time* lt)
499 0)] ; already measured on parallel thread
500 (render! content))))))
502 (defn- fps-label [text]
503 (padding (label text :right :bottom) 5))
505 (defn fps-layer
506 "Creates layer that draws content and displays
507 the frames per seconds rate."
508 [content]
509 (let [update-interval 2E8 ; 0.2 s in nanoseconds
510 frames (ref 0)
511 prev-time (ref nil)
512 display (ref (fps-label "fps n/a"))]
513 (decorate-layer content [_]
514 (draw! content)
515 (draw!
516 (dosync
517 (alter frames inc)
518 (if @prev-time
519 (let [elapsed (- *time* @prev-time)]
520 (when (> elapsed update-interval)
521 (let [fps (/ @frames (/ elapsed 1E9))]
522 (ref-set display (fps-label (format "%.1f" fps)))
523 (ref-set frames 0)
524 (ref-set prev-time *time*))))
525 (ref-set prev-time *time*))
526 @display)))))
528 ;;
529 ;; Overlayer.
530 ;;
532 (def ^:private ^:dynamic *above*)
534 (defn- overlay* [f & args]
535 (var-set #'*above* (conj *above* (apply partial f args))))
537 (defn- ^Point to-graphics-coords
538 [^AffineTransform transform x y]
539 (let [p (Point. x y)]
540 (.transform transform p p)
541 (.transform (.createInverse (.getTransform *graphics*)) p p)
542 p))
544 (defn- draw-relative!
545 ([layer transform x y]
546 (let [p (to-graphics-coords transform x y)]
547 (draw! layer (.x p) (.y p))))
548 ([layer transform x y w h]
549 (let [p (to-graphics-coords transform x y)]
550 (draw! layer (.x p) (.y p) w h))))
552 (defn- draw-relative-aligned!
553 [layer transform h-align v-align x y]
554 (let [geom (geometry layer)
555 w (width geom)
556 h (height geom)
557 p (to-graphics-coords transform x y)
558 x (- (.x p) (anchor-x geom h-align w))
559 y (- (.y p) (anchor-y geom v-align h))]
560 (draw! layer x y w h)))
562 (defn overlay!
563 "Draws layer in the overlayer context above the other layers."
564 ([layer]
565 (overlay* draw-relative! layer (.getTransform *graphics*) 0 0))
566 ([layer x y]
567 (overlay* draw-relative! layer (.getTransform *graphics*) x y))
568 ([layer x y w h]
569 (overlay* draw-relative! layer (.getTransform *graphics*) x y w h)))
571 (defn overlay-aligned! [layer h-align v-align x y]
572 (overlay* draw-relative-aligned!
573 layer (.getTransform *graphics*)
574 h-align v-align x y))
576 (defn overlayer
577 [content]
578 (decorate-layer content [_]
579 (binding [*above* []]
580 (render! content)
581 (doseq [f *above*]
582 (f)))))
584 (defn overlayer*
585 [content]
586 (decorate-layer content [_]
587 (binding [*above* []]
588 (render! content)
589 (loop [above *above*]
590 (when (seq above)
591 (var-set #'*above* [])
592 (doseq [f above]
593 (f))
594 (recur *above*))))))