view src/net/kryshen/indyvon/layers.clj @ 101:9874107e3e96

Clojure 1.3 compatibility, mouse wheel support, scalable viewport, additional layer implementations.
author Mikhail Kryshen <mikhail@kryshen.net>
date Wed, 18 May 2011 20:50:49 +0400
parents ad09a826ebaf
children 9b81174f0511
line source
1 ;;
2 ;; Copyright 2010, 2011 Mikhail Kryshen <mikhail@kryshen.net>
3 ;;
4 ;; This file is part of Indyvon.
5 ;;
6 ;; Indyvon is free software: you can redistribute it and/or modify it
7 ;; under the terms of the GNU Lesser General Public License version 3
8 ;; only, as published by the Free Software Foundation.
9 ;;
10 ;; Indyvon is distributed in the hope that it will be useful, but
11 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 ;; Lesser General Public License for more details.
14 ;;
15 ;; You should have received a copy of the GNU Lesser General Public
16 ;; License along with Indyvon. If not, see
17 ;; <http://www.gnu.org/licenses/>.
18 ;;
20 (ns net.kryshen.indyvon.layers
21 "Implementations of Layer protocol."
22 (:use
23 (net.kryshen.indyvon core async))
24 (:import
25 (net.kryshen.indyvon.core Size Location)
26 (java.lang.ref SoftReference)
27 (java.awt Font Cursor Image Toolkit Point)
28 java.awt.image.ImageObserver
29 (java.awt.geom AffineTransform Point2D$Double)
30 (java.awt.font FontRenderContext TextLayout)))
32 ;; Define as macro to avoid unnecessary calculation of inner and outer
33 ;; sizes in the first case.
34 (defmacro align-xy [inner outer align first center last]
35 `(case ~align
36 ~first 0
37 ~center (/ (- ~outer ~inner) 2)
38 ~last (- ~outer ~inner)))
40 (defmacro align-x [inner outer align]
41 `(align-xy ~inner ~outer ~align :left :center :right))
43 (defmacro align-y [inner outer align]
44 `(align-xy ~inner ~outer ~align :top :center :bottom))
46 (defmacro decorate-layer
47 "Decorate Layer and Anchored replacing render! implementation."
48 [layer & render-tail]
49 `(reify
50 Layer
51 (render! ~@render-tail)
52 (layer-size [t#] (layer-size ~layer))
53 Anchored
54 (anchor [t# xa# ya#] (anchor ~layer xa# ya#))))
56 (defn padding
57 "Decorates layer adding padding."
58 ([content pad]
59 (padding content pad pad pad pad))
60 ([content top left bottom right]
61 (if (== 0 top left bottom right)
62 content
63 (reify
64 Layer
65 (render! [l]
66 (draw! content
67 left top
68 (- *width* left right)
69 (- *height* top bottom)))
70 (layer-size [l]
71 (let [s (layer-size content)]
72 (Size. (+ (:width s) left right)
73 (+ (:height s) top bottom))))))))
75 (defn border
76 "Decorate layer with a border."
77 ([content]
78 (border content 1))
79 ([content width]
80 (border content width 0))
81 ([content width gap]
82 (let [layer (padding content (+ width gap))]
83 (decorate-layer layer [_]
84 (with-color :border-color
85 (doseq [i (range 0 width)]
86 (.drawRect *graphics* i i
87 (- *width* 1 i i)
88 (- *height* 1 i i))))
89 (render! layer)))))
91 ;; TODO: opacity and blur.
92 (defn shadow
93 "Add shadow to content layer."
94 ([content]
95 (shadow content 1 1))
96 ([content x-offset y-offset]
97 (let [x (if (neg? x-offset) (- x-offset) 0)
98 y (if (neg? y-offset) (- y-offset) 0)
99 abs-x (if (neg? x-offset) (- x-offset) x-offset)
100 abs-y (if (neg? y-offset) (- y-offset) y-offset)
101 shadow-x (+ x-offset x)
102 shadow-y (+ y-offset y)]
103 (reify
104 ;; TODO: Anchored
105 Layer
106 (render! [_]
107 (let [w (- *width* abs-x)
108 h (- *height* abs-y)]
109 (with-color :shadow-color
110 (.fillRect *graphics* shadow-x shadow-y w h))
111 (draw! content x y w h)))
112 (layer-size [_]
113 (let [s (layer-size content)]
114 (Size. (+ (:width s) abs-x)
115 (+ (:height s) abs-y))))))))
117 (defn panel
118 "Opaque layer using theme's alt-back-color."
119 ([content]
120 (panel content 0))
121 ([content gap]
122 (let [layer (padding content gap)]
123 (decorate-layer layer [_]
124 (with-color :alt-back-color
125 (.fillRect *graphics* 0 0 *width* *height*))
126 (render! layer)))))
128 (defn hbox
129 "Creates layer that draws the specified content layers placing them
130 horizontally."
131 [& contents]
132 (reify
133 Layer
134 (render! [_]
135 (let [widths (map #(:width (layer-size %)) contents)
136 xs (cons 0 (reductions + widths))
137 widths-sum (last xs)
138 scale (/ *width* widths-sum)]
139 (doseq [[c w x] (map vector contents widths xs)]
140 (draw! c x 0 w *height*))))
141 (layer-size [_]
142 (reduce #(Size. (+ (:width %1) (:width %2))
143 (max (:height %1) (:height %2)))
144 (Size. 0 0)
145 (map layer-size contents)))))
147 (defn vbox
148 "Creates layer that draws the specified content layers placing them
149 vertically."
150 [& contents]
151 (reify
152 Layer
153 (render! [_]
154 (let [heights (map #(:height (layer-size %)) contents)
155 ys (cons 0 (reductions + heights))
156 heights-sum (last ys)
157 scale (/ *height* heights-sum)]
158 (doseq [[c h y] (map vector contents heights ys)]
159 (draw! c 0 y *width* h))))
160 (layer-size [_]
161 (reduce #(Size. (max (:width %1) (:width %2))
162 (+ (:height %1) (:height %2)))
163 (Size. 0 0)
164 (map layer-size contents)))))
166 (defn- re-split [^java.util.regex.Pattern re s]
167 (seq (.split re s)))
169 (def ^:private text-layout-cache (atom {}))
171 (defn- get-text-layout
172 [^String line ^Font font ^FontRenderContext font-context]
173 (let [key [line font font-context]]
174 (or (if-let [^SoftReference softref (@text-layout-cache key)]
175 (.get softref)
176 (do (swap! text-layout-cache dissoc key)
177 false))
178 (let [layout (TextLayout. line font font-context)]
179 ;;(println "text-layout-cache miss" line)
180 (swap! text-layout-cache assoc key (SoftReference. layout))
181 layout))))
183 (defn- layout-text
184 [lines ^Font font ^FontRenderContext font-context]
185 (map #(get-text-layout % font font-context) lines))
186 ;;(map #(TextLayout. ^String % font font-context) lines))
188 (defn- text-width [layouts]
189 (reduce (fn [w ^TextLayout tl] (max w (.getAdvance tl))) 0 layouts))
191 (defn- text-height [layouts]
192 (reduce (fn [w ^TextLayout tl]
193 (+ w (.getAscent tl)
194 (.getDescent tl)
195 (.getLeading tl)))
196 0 layouts))
198 (defn label
199 "Creates a layer to display multiline text."
200 ([text]
201 (label text :left :top))
202 ([text h-align v-align]
203 (let [lines (re-split #"\r\n|\n|\r|\u0085|\u2028|\u2029" (str text))]
204 (reify Layer
205 (render! [layer]
206 (let [w *width*
207 h *height*
208 font (.getFont *graphics*)
209 layouts (layout-text lines font *font-context*)
210 y (align-y (text-height layouts) h v-align)]
211 (loop [layouts layouts, y y]
212 (when-first [^TextLayout layout layouts]
213 (let [ascent (.getAscent layout)
214 lh (+ ascent (.getDescent layout) (.getLeading layout))
215 x (align-x (.getAdvance layout) w h-align)]
216 (.draw layout *graphics* x (+ y ascent))
217 (recur (next layouts) (+ y lh)))))))
218 (layer-size [layer]
219 (let [layouts (layout-text lines (:font *theme*) *font-context*)
220 width (text-width layouts)
221 height (text-height layouts)]
222 (Size. width height)))))))
224 (defn- ^ImageObserver image-observer [layer]
225 (reify
226 ImageObserver
227 (imageUpdate [this img infoflags x y width height]
228 (update layer)
229 (zero? (bit-and infoflags
230 (bit-or ImageObserver/ALLBITS
231 ImageObserver/ABORT))))))
233 (defn image-layer
234 [image-or-uri]
235 (let [^Image image (if (instance? Image image-or-uri)
236 image-or-uri
237 (.getImage (Toolkit/getDefaultToolkit)
238 ^java.net.URL image-or-uri))]
239 (.prepareImage (Toolkit/getDefaultToolkit) image -1 -1 nil)
240 (reify
241 Layer
242 (render! [layer]
243 (repaint-on-update layer)
244 (.drawImage *graphics* image 0 0 (image-observer layer)))
245 (layer-size [layer]
246 (let [observer (image-observer layer)
247 width (.getWidth image observer)
248 height (.getHeight image observer)
249 width (if (pos? width) width 1)
250 height (if (pos? height) height 1)]
251 (Size. width height))))))
253 (def ^{:dynamic true} *miniature-thread-priority* 2)
255 (defn- scaling
256 [width height max-width max-height]
257 (min (/ max-width width)
258 (/ max-height height)))
260 (defn miniature
261 "Creates layer that asynchronously renders view of the content
262 scaled to the specified size."
263 [content width height]
264 (async-layer
265 (reify
266 Layer
267 (render! [this]
268 (let [size (layer-size content)
269 s (scaling (:width size) (:height size) width height)]
270 (.scale *graphics* s s)
271 (draw! content
272 (align-x (:width size) (/ width s) :center)
273 (align-y (:height size) (/ height s) :center)
274 (:width size) (:height size))))
275 (layer-size [this]
276 (Size. width height)))
277 ;; (let [size (layer-size content)
278 ;; s (scaling (:width size) (:height size) width height)]
279 ;; (Size. (* (:width size) s) (* (:height size) s)))))
280 width height *miniature-thread-priority*))
282 ;;(defn- translate [^AffineTransform transform ^double x ^double y]
283 ;; (doto ^AffineTransform (.clone transform)
284 ;; (.translate x y)))
286 (defn- scale [^AffineTransform transform ^double sx ^double sy]
287 (doto ^AffineTransform (.clone transform)
288 (.scale sx sy)))
290 (defn- pre-translate [^AffineTransform transform ^double x ^double y]
291 (if (== 0.0 x y)
292 transform
293 (doto (AffineTransform/getTranslateInstance x y)
294 (.concatenate transform))))
296 (def ^{:dynamic true} *viewport-scaling-step* (double 3/4))
297 (def ^{:dynamic true} *viewport-min-scale* 1E-6)
298 (def ^{:dynamic true} *viewport-max-scale* 1E6)
300 (defrecord Viewport [content h-align v-align
301 ;; State (refs)
302 transform
303 fix-x fix-y
304 last-width last-height last-anchor]
305 Layer
306 (render! [layer]
307 (repaint-on-update layer)
308 (with-handlers layer
309 (let [anchor (anchor content h-align v-align)]
310 (dosync
311 (let [ax1 (align-x @last-width *width* h-align)
312 ay1 (align-y @last-height *height* v-align)
313 ax2 (- (:x @last-anchor) (:x anchor))
314 ay2 (- (:y @last-anchor) (:y anchor))]
315 (if-not (and (zero? ax1) (zero? ay1) (zero? ax2) (zero? ay2))
316 (ref-set transform
317 (doto (AffineTransform/getTranslateInstance ax1 ay1)
318 (.concatenate @transform)
319 (.translate ax2 ay2)))))
320 (ref-set last-width *width*)
321 (ref-set last-height *height*)
322 (ref-set last-anchor anchor))
323 ;; TODO: notify observers when size changes.
324 (with-transform @transform
325 (draw! content 0 0 false)))
326 (:mouse-pressed e
327 (dosync
328 (ref-set fix-x (:x-on-screen e))
329 (ref-set fix-y (:y-on-screen e)))
330 (when *target*
331 (->> Cursor/MOVE_CURSOR Cursor. (.setCursor *target*))))
332 (:mouse-released e
333 (when *target*
334 (->> Cursor/DEFAULT_CURSOR Cursor. (.setCursor *target*))))
335 (:mouse-dragged e
336 (dosync
337 (alter transform pre-translate
338 (- (:x-on-screen e) @fix-x)
339 (- (:y-on-screen e) @fix-y))
340 (ref-set fix-x (:x-on-screen e))
341 (ref-set fix-y (:y-on-screen e)))
342 (update layer))
343 (:mouse-wheel e
344 (dosync
345 (let [s (Math/pow *viewport-scaling-step* (:wheel-rotation e))
346 x (- (:x e) (* (:x e) s))
347 y (- (:y e) (* (:y e) s))
348 scaled (doto (AffineTransform/getTranslateInstance x y)
349 (.scale s s)
350 (.concatenate @transform))
351 sx (.getScaleX scaled)
352 sy (.getScaleY scaled)]
353 (if (<= *viewport-min-scale*
354 (min sx sy)
355 (max sx sy)
356 *viewport-max-scale*)
357 (ref-set transform scaled))))
358 (update layer))))
359 (layer-size [layer]
360 (layer-size content)))
362 (defn viewport
363 "Creates scrollable viewport layer."
364 ([content]
365 (viewport content :left :top))
366 ([content h-align v-align]
367 (Viewport. content h-align v-align
368 (ref (AffineTransform.)) ; transform
369 (ref 0) (ref 0) ; fix-x fix-y
370 (ref 0) (ref 0) ; last-width last-height
371 (ref (Location. 0 0))))) ; last-anchor
373 (defn reset-viewport [viewport]
374 (dosync
375 (ref-set (:last-width viewport) 0)
376 (ref-set (:last-height viewport) 0)
377 (ref-set (:last-anchor viewport) (Location. 0 0))
378 (ref-set (:transform viewport) (AffineTransform.)))
379 (update viewport))
381 (defn viewport-miniature
382 "Creates miniature view of the viewport's contents."
383 [viewport width height]
384 (let [miniature (miniature (:content viewport) width height)]
385 (decorate-layer miniature [l]
386 (repaint-on-update viewport)
387 (let [size (layer-size (:content viewport))
388 s (scaling (:width size) (:height size) width height)
389 [vp-tr w h] (dosync
390 [@(:transform viewport)
391 @(:last-width viewport)
392 @(:last-height viewport)])
393 vp-inverse (.createInverse ^AffineTransform vp-tr)
394 ox (align-x (:width size) (/ width s) :center)
395 oy (align-y (:height size) (/ height s) :center)
396 transform (doto (AffineTransform.)
397 (.scale s s)
398 (.translate ox oy)
399 (.concatenate vp-inverse))
400 move-vp (fn [x y]
401 (dosync
402 (let [x (- (/ x s) ox)
403 y (- (/ y s) oy)
404 [x y] (transform-point @(:transform viewport)
405 x y)
406 x (- x (/ @(:last-width viewport) 2))
407 y (- y (/ @(:last-height viewport) 2))]
408 (alter (:transform viewport)
409 pre-translate (- x) (- y))))
410 (update viewport))]
411 (with-color :alt-back-color
412 (.fillRect *graphics* 0 0 *width* *height*))
413 (with-transform transform
414 (with-color :back-color
415 (.fillRect *graphics* 0 0 w h)))
416 (with-handlers l
417 (draw! miniature)
418 (:mouse-pressed e (move-vp (:x e) (:y e)))
419 (:mouse-dragged e (move-vp (:x e) (:y e))))
420 (with-transform transform
421 (with-color :border-color
422 (.drawRect *graphics* 0 0 w h)))))))
424 (defn ref-layer
425 [layer-ref]
426 (let [l (reify
427 Layer
428 (render! [l]
429 (repaint-on-update l)
430 (if-let [layer @layer-ref]
431 (render! layer)))
432 (layer-size [_]
433 (if-let [layer @layer-ref]
434 (layer-size layer)
435 (Size. 1 1)))
436 Anchored
437 (anchor [_ x-align y-align]
438 (if-let [layer @layer-ref]
439 (anchor layer x-align y-align)
440 (Location. 0 0))))]
441 (add-watch layer-ref l (fn [_ _ _ _] (update l)))
442 l))
444 ;;
445 ;; Layer context decorators.
446 ;;
448 (defmacro handler [layer & handlers]
449 "Decorate layer to handle events."
450 `(let [layer# ~layer]
451 (decorate-layer layer# [t#]
452 (with-handlers t#
453 (render! layer#)
454 ~@handlers))))
456 (defn themed [layer & map-or-keyvals]
457 (let [theme (if (== (count map-or-keyvals) 1)
458 (first map-or-keyvals)
459 (apply array-map map-or-keyvals))]
460 (reify
461 Layer
462 (render! [t]
463 (with-theme theme
464 (render! layer)))
465 (layer-size [t]
466 (with-theme theme
467 (layer-size layer)))
468 Anchored
469 (anchor [t xa ya]
470 (with-theme theme
471 (anchor layer xa ya))))))
473 (defn hinted [layer & map-or-keyvals]
474 (let [hints (if (== (count map-or-keyvals) 1)
475 (first map-or-keyvals)
476 (apply array-map map-or-keyvals))]
477 (decorate-layer layer [_]
478 (with-hints* hints render! layer))))
480 ;;
481 ;; Measuring time
482 ;;
484 (def ^{:dynamic true} *interval*)
486 (defn interval-layer
487 "Creates layer that measures time between repaints ant draws it's
488 content with the *interval* var bound to the measured time."
489 [content]
490 (let [last-time (atom nil)]
491 (decorate-layer content [_]
492 (compare-and-set! last-time nil *time*)
493 (let [lt @last-time]
494 (binding [*interval* (if (compare-and-set! last-time lt *time*)
495 (- *time* lt)
496 0)] ; already measured on parallel thread
497 (render! content))))))
499 (defn- fps-label [text]
500 (padding (label text :right :bottom) 5))
502 (defn fps-layer
503 "Creates layer that draws content and displays
504 the frames per seconds rate."
505 [content]
506 (let [update-interval 2E8 ; 0.2 s in nanoseconds
507 frames (ref 0)
508 prev-time (ref nil)
509 display (ref (fps-label "fps n/a"))]
510 (decorate-layer content [_]
511 (draw! content)
512 (draw!
513 (dosync
514 (alter frames inc)
515 (if @prev-time
516 (let [elapsed (- *time* @prev-time)]
517 (when (> elapsed update-interval)
518 (let [fps (/ @frames (/ elapsed 1E9))]
519 (ref-set display (fps-label (format "%.1f" fps)))
520 (ref-set frames 0)
521 (ref-set prev-time *time*))))
522 (ref-set prev-time *time*))
523 @display)))))
525 ;;
526 ;; Overlayer.
527 ;;
529 (def ^{:private true :dynamic true} *above*)
531 (defn- overlay* [f & args]
532 (var-set #'*above* (conj *above* (apply partial f args))))
534 (defn- ^Point to-graphics-coords
535 [^AffineTransform transform x y]
536 (let [p (Point. x y)]
537 (.transform transform p p)
538 (.transform (.createInverse (.getTransform *graphics*)) p p)
539 p))
541 (defn- draw-relative!
542 ([layer transform x y]
543 (let [p (to-graphics-coords transform x y)]
544 (draw! layer (.x p) (.y p))))
545 ([layer transform x y w h]
546 (let [p (to-graphics-coords transform x y)]
547 (draw! layer (.x p) (.y p) w h))))
549 (defn overlay!
550 "Draws layer in the overlayer context above the other layers."
551 ([layer]
552 (overlay* draw-relative! layer (.getTransform *graphics*) 0 0))
553 ([layer x y]
554 (overlay* draw-relative! layer (.getTransform *graphics*) x y))
555 ([layer x y w h]
556 (overlay* draw-relative! layer (.getTransform *graphics*) x y w h)))
558 (defn overlayer
559 [content]
560 (decorate-layer content [_]
561 (binding [*above* []]
562 (render! content)
563 (doseq [f *above*]
564 (f)))))