view src/net/kryshen/indyvon/layers.clj @ 67:a19cf5007d14

Asynchronous drawing.
author Mikhail Kryshen <mikhail@kryshen.net>
date Sat, 28 Aug 2010 02:37:30 +0400
parents a1999c1f7289
children 9b511fe09867
line source
1 ;;
2 ;; Copyright (C) 2010 Mikhail Kryshen <mikhail@kryshen.net>
3 ;;
4 ;; This file is part of Indyvon.
5 ;;
7 (ns net.kryshen.indyvon.layers
8 "Implementations of Layer protocol."
9 (:use
10 (net.kryshen.indyvon core async))
11 (:import
12 (net.kryshen.indyvon.core Size Location)
13 (java.lang.ref SoftReference)
14 (java.awt Font Cursor Image Toolkit)
15 (java.awt.image ImageObserver)
16 (java.awt.font FontRenderContext TextLayout)))
18 ;; Define as macro to avoid unnecessary calculation of inner and outer
19 ;; sizes in the first case.
20 (defmacro align-xy [inner outer align first center last]
21 `(case ~align
22 ~first 0
23 ~center (/ (- ~outer ~inner) 2)
24 ~last (- ~outer ~inner)))
26 (defmacro align-x [inner outer align]
27 `(align-xy ~inner ~outer ~align :left :center :right))
29 (defmacro align-y [inner outer align]
30 `(align-xy ~inner ~outer ~align :top :center :bottom))
32 (defmacro decorate-layer
33 "Decorate Layer and Anchored replacing render! implementation."
34 [layer & render-tail]
35 `(reify
36 Layer
37 (render! ~@render-tail)
38 (layer-size [t#] (layer-size ~layer))
39 Anchored
40 (anchor [t# xa# ya#] (anchor ~layer xa# ya#))))
42 (defn padding
43 "Decorates layer adding padding."
44 ([content pad]
45 (padding content pad pad pad pad))
46 ([content top left bottom right]
47 (if (== 0 top left bottom right)
48 content
49 (reify
50 Layer
51 (render! [l]
52 (draw! content
53 left top
54 (- *width* left right)
55 (- *height* top bottom)))
56 (layer-size [l]
57 (let [s (layer-size content)]
58 (Size. (+ (:width s) left right)
59 (+ (:height s) top bottom))))))))
61 (defn border
62 "Decorate layer with a border."
63 ([content]
64 (border content 1))
65 ([content width]
66 (border content width 0))
67 ([content width gap]
68 (let [layer (padding content (+ width gap))]
69 (decorate-layer layer [_]
70 (with-color (:border-color *theme*)
71 (doseq [i (range 0 width)]
72 (.drawRect *graphics* i i
73 (- *width* 1 i i)
74 (- *height* 1 i i))))
75 (render! layer)))))
77 (defn panel
78 "Opaque layer using theme's alt-back-color."
79 ([content]
80 (panel content 0))
81 ([content gap]
82 (let [layer (padding content gap)]
83 (decorate-layer layer [_]
84 (with-color (:alt-back-color *theme*)
85 (.fillRect *graphics* 0 0 *width* *height*))
86 (render! layer)))))
88 (defn- re-split [^java.util.regex.Pattern re s]
89 (seq (.split re s)))
91 (def text-layout-cache (atom {}))
93 (defn- get-text-layout
94 [^String line ^Font font ^FontRenderContext font-context]
95 (let [key [line font font-context]]
96 (or (if-let [^SoftReference softref (@text-layout-cache key)]
97 (.get softref)
98 (do (swap! text-layout-cache dissoc key)
99 false))
100 (let [layout (TextLayout. line font font-context)]
101 ;;(println "text-layout-cache miss" line)
102 (swap! text-layout-cache assoc key (SoftReference. layout))
103 layout))))
105 (defn- layout-text
106 [lines ^Font font ^FontRenderContext font-context]
107 (map #(get-text-layout % font font-context) lines))
108 ;;(map #(TextLayout. ^String % font font-context) lines))
110 (defn- text-width [layouts]
111 (reduce (fn [w ^TextLayout tl] (max w (.getAdvance tl))) 0 layouts))
113 (defn- text-height [layouts]
114 (reduce (fn [w ^TextLayout tl] (+ w (.getAscent tl)
115 (.getDescent tl)
116 (.getLeading tl)))
117 0 layouts))
119 (defn text-layer
120 "Creates a layer to display multiline text."
121 ([text]
122 (text-layer text :left :top))
123 ([text h-align v-align]
124 (let [lines (re-split #"\r\n|\n|\r|\u0085|\u2028|\u2029" text)]
125 (reify Layer
126 (render! [layer]
127 (let [w *width*
128 h *height*
129 font (.getFont *graphics*)
130 layouts (layout-text lines font *font-context*)
131 y (align-y (text-height layouts) h v-align)]
132 (loop [layouts layouts, y y]
133 (when-first [^TextLayout layout layouts]
134 (let [ascent (.getAscent layout)
135 lh (+ ascent (.getDescent layout) (.getLeading layout))
136 x (align-x (.getAdvance layout) w h-align)]
137 (.draw layout *graphics* x (+ y ascent))
138 (recur (next layouts) (+ y lh)))))))
139 (layer-size [layer]
140 (let [layouts (layout-text lines (:font *theme*) *font-context*)
141 width (text-width layouts)
142 height (text-height layouts)]
143 (Size. width height)))))))
145 (defn- ^ImageObserver image-observer [layer]
146 (reify
147 ImageObserver
148 (imageUpdate [this img infoflags x y width height]
149 (update layer)
150 (zero? (bit-and infoflags
151 (bit-or ImageObserver/ALLBITS
152 ImageObserver/ABORT))))))
154 (defn image-layer
155 [image-or-uri]
156 (let [^Image image (if (isa? image-or-uri Image)
157 image-or-uri
158 (.getImage (Toolkit/getDefaultToolkit)
159 ^java.net.URL image-or-uri))]
160 (.prepareImage (Toolkit/getDefaultToolkit) image -1 -1 nil)
161 (reify
162 Layer
163 (render! [layer]
164 (repaint-on-update layer)
165 (.drawImage *graphics* image 0 0 (image-observer layer)))
166 (layer-size [layer]
167 (let [observer (image-observer layer)
168 width (.getWidth image observer)
169 height (.getHeight image observer)
170 width (if (pos? width) width 1)
171 height (if (pos? height) height 1)]
172 (Size. width height))))))
174 (defn miniature
175 "Creates layer that asynchronously renders view of the content
176 scaled to the specified size."
177 [content width height]
178 (async-layer
179 (reify
180 Layer
181 (render! [this]
182 (let [size (layer-size content)
183 sx (/ width (:width size))
184 sy (/ height (:height size))]
185 (.scale *graphics* sx sy)
186 (draw! content 0 0 (:width size) (:height size))))
187 (layer-size [this]
188 (Size. width height)))
189 width height))
191 (defn viewport
192 "Creates scrollable viewport layer."
193 ([content] (viewport content :left :top))
194 ([content h-align v-align]
195 (let [x (ref 0)
196 y (ref 0)
197 fix-x (ref 0)
198 fix-y (ref 0)
199 last-width (ref 0)
200 last-height (ref 0)]
201 (reify
202 Layer
203 (render! [layer]
204 (repaint-on-update layer)
205 (with-handlers layer
206 (let [anchor (anchor content h-align v-align)]
207 (dosync
208 (alter x + (align-x *width* @last-width h-align))
209 (alter y + (align-y *height* @last-height v-align))
210 (ref-set last-width *width*)
211 (ref-set last-height *height*))
212 (draw! content (- 0 @x (:x anchor)) (- 0 @y (:y anchor))))
213 (:mouse-pressed e
214 (dosync
215 (ref-set fix-x (:x-on-screen e))
216 (ref-set fix-y (:y-on-screen e)))
217 (when *target*
218 (->> Cursor/MOVE_CURSOR Cursor. (.setCursor *target*))))
219 (:mouse-released e
220 (when *target*
221 (->> Cursor/DEFAULT_CURSOR Cursor. (.setCursor *target*))))
222 (:mouse-dragged e
223 (dosync
224 (alter x + (- @fix-x (:x-on-screen e)))
225 (alter y + (- @fix-y (:y-on-screen e)))
226 (ref-set fix-x (:x-on-screen e))
227 (ref-set fix-y (:y-on-screen e)))
228 (update layer))))
229 (layer-size [layer] (layer-size content))))))
231 ;;
232 ;; Layer context decorators.
233 ;;
235 (defmacro handler [layer & handlers]
236 "Decorate layer to handle events."
237 `(let [layer# ~layer]
238 (decorate-layer layer# [t#]
239 (with-handlers t#
240 (render! layer#)
241 ~@handlers))))
243 (defn theme [layer & map-or-keyvals]
244 (let [theme (if (== (count map-or-keyvals) 1)
245 map-or-keyvals
246 (apply array-map map-or-keyvals))]
247 (reify
248 Layer
249 (render! [t]
250 (with-theme theme
251 (render! layer)))
252 (layer-size [t]
253 (with-theme theme
254 (layer-size layer)))
255 Anchored
256 (anchor [t xa ya]
257 (with-theme theme
258 (anchor layer xa ya))))))