;;
;; Copyright (C) 2010 Mikhail Kryshen <mikhail@kryshen.net>
;;
;; This file is part of Indyvon.
;;

(ns kryshen.indyvon.component
  (:use
   kryshen.indyvon.core)
  (:import
   (kryshen.indyvon.core Size Bounds)
   (java.awt Graphics2D Component Dimension Color)
   (javax.swing JFrame JPanel)))

(defn- font-context [^Component component]
  (.getFontRenderContext (.getFontMetrics component (.getFont component))))

(defn paint-component
  [^Component component layer ^Graphics2D graphics event-dispatcher]
  (let [size (.getSize component)
        width (.width size)
        height (.height size)]
    (.clearRect graphics 0 0 width height)
    (let [bounds (Bounds. 0 0 width height)]
      (binding [*graphics* graphics
                *font-context* (.getFontRenderContext graphics)
                *target* component
                *event-dispatcher* event-dispatcher
                *update* #(.repaint component)
                *bounds* bounds
                *clip* bounds]
        (render! layer)
        (commit event-dispatcher)))))

(defn preferred-size [component layer]
  (binding [*target* component
            *font-context*' (font-context component)]
    (let [s (layer-size layer)]
      (Dimension. (:width s) (:height s)))))

(defn make-jpanel
  ([layer]
     (make-jpanel layer (root-event-dispatcher)))
  ([layer event-dispatcher]
     (let [panel
           (proxy [JPanel] []
             (paintComponent [g]
                (paint-component this layer g event-dispatcher))
             (getPreferredSize []
                (preferred-size this layer)))]
       (.setBackground panel (:back-color *theme*))
       (listen! event-dispatcher panel)
       panel)))