Mercurial > hg > indyvon
view src/net/kryshen/indyvon/core.clj @ 85:e718a69f7d99
Observers: use weak keys, renamed some fns.
| author | Mikhail Kryshen <mikhail@kryshen.net> |
|---|---|
| date | Fri, 01 Oct 2010 18:45:17 +0400 |
| parents | 5d2153e8a28d |
| children | beb89bd18839 |
line source
1 ;;
2 ;; Copyright 2010 Mikhail Kryshen <mikhail@kryshen.net>
3 ;;
4 ;; This file is part of Indyvon.
5 ;;
6 ;; Indyvon is free software: you can redistribute it and/or modify it
7 ;; under the terms of the GNU Lesser General Public License version 3
8 ;; only, as published by the Free Software Foundation.
9 ;;
10 ;; Indyvon is distributed in the hope that it will be useful, but
11 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 ;; Lesser General Public License for more details.
14 ;;
15 ;; You should have received a copy of the GNU Lesser General Public
16 ;; License along with Indyvon. If not, see
17 ;; <http://www.gnu.org/licenses/>.
18 ;;
20 (ns net.kryshen.indyvon.core
21 (:import
22 (java.awt Graphics2D RenderingHints Component Color Font Shape)
23 (java.awt.geom AffineTransform Point2D$Double Rectangle2D$Double Area)
24 (java.awt.event MouseListener MouseMotionListener)
25 (java.awt.font FontRenderContext)
26 (com.google.common.collect MapMaker)))
28 ;;
29 ;; Layer context
30 ;;
32 (def ^Graphics2D *graphics*)
34 (def ^FontRenderContext *font-context*)
36 (def ^{:tag Component
37 :doc "Target AWT component, may be nil if drawing off-screen."}
38 *target*)
40 (def ^{:doc "Width of the rendering area."}
41 *width*)
43 (def ^{:doc "Height of the rendering area."}
44 *height*)
46 (def ^Shape *clip*)
48 (def ^{:doc "The root (background) layer of the scene."}
49 *root*)
51 (def ^{:doc "Time in nanoseconds when the rendering of the current
52 frame starts."}
53 *time*)
55 (def *event-dispatcher*)
57 (def ^{:tag AffineTransform
58 :doc "Initial transform associated with the graphics context."}
59 *initial-transform*)
61 (def ^{:tag AffineTransform
62 :doc "Inversion of the initial transform associated with
63 the graphics context."}
64 *inverse-initial-transform*)
66 (defrecord Theme [fore-color back-color alt-back-color border-color font])
68 ;; REMIND: use system colors, see java.awt.SystemColor.
69 (defn default-theme []
70 (Theme. Color/BLACK Color/WHITE Color/LIGHT_GRAY
71 Color/BLUE (Font. "Sans" Font/PLAIN 12)))
73 (def *theme* (default-theme))
75 (defrecord Location [x y])
76 (defrecord Size [width height])
77 (defrecord Bounds [x y width height])
79 ;;
80 ;; Core protocols and types
81 ;;
83 (defprotocol Layer
84 "Basic UI element."
85 (render! [this])
86 (layer-size [this]))
88 ;; TODO: modifiers
89 (defrecord MouseEvent [id when x y x-on-screen y-on-screen button])
91 ;; TODO: KeyEvent
93 (defprotocol EventDispatcher
94 (listen! [this ^Component component]
95 "Listen for events on the specified AWT Component.")
96 (create-dispatcher [this handle handlers]
97 "Returns new event dispatcher associated with the specified event
98 handlers (an event-id -> handler-fn map). Handle is used to
99 match the contexts between commits.")
100 (commit [this]
101 "Apply the registered handlers for event processing.")
102 (handle-picked? [this handle]
103 "Returns true if the specified handle received the :mouse-pressed
104 event and have not yet received :moused-released.")
105 (handle-hovered? [this handle]
106 "Returns true if the specified handle received the :mouse-entered
107 event and have not yet received :mouse-exited."))
109 (defprotocol Anchored
110 "Provide anchor point for Layers. Used by viewport."
111 (anchor [this h-align v-align]
112 "Anchor point: [x y], h-align could be :left, :center or :right,
113 v-align is :top, :center or :bottom"))
115 (defn default-anchor [layer h-align v-align]
116 (if (and (= h-align :left)
117 (= v-align :top))
118 (Location. 0 0)
119 (let [size (layer-size layer)]
120 (Location.
121 (case h-align
122 :top 0
123 :center (/ (:width size) 2)
124 :right (:width size))
125 (case v-align
126 :left 0
127 :center (/ (:height size) 2)
128 :bottom (:height size))))))
130 ;; Default implementation of Anchored for any Layer.
131 (extend-protocol Anchored
132 net.kryshen.indyvon.core.Layer
133 (anchor [this h-align v-align]
134 (default-anchor this h-align v-align)))
136 (defn- assoc-cons [m key val]
137 (->> (get m key) (cons val) (assoc m key)))
139 ;;
140 ;; Observers
141 ;; The mechanism used by layers to request repaints
142 ;;
144 (def ^java.util.Map observers
145 (-> (MapMaker.) (.weakKeys) (.makeMap)))
147 (defn add-observer
148 "Add observer fn for the target. Watcher identifies the group of
149 observers and could be used to remove the group. Watcher is weakly
150 referenced, all associated observers will be removed when the
151 wathcer is removed by gc. The observer fn will be called with
152 watcher and target arguments and any additional arguments specified
153 in update call."
154 [watcher target f]
155 (.put observers watcher (assoc-cons (.get observers watcher) target f))
156 nil)
158 (defn remove-observers
159 "Remove group of observers associated with the specified watcher."
160 [watcher]
161 (.remove observers watcher)
162 nil)
164 (defn- replace-observers-watcher
165 [old-watcher new-watcher]
166 (if-let [old (.remove observers old-watcher)]
167 (.put observers new-watcher old))
168 nil)
170 (defn update
171 "Notify observers."
172 [target & args]
173 (doseq [entry observers
174 f (get (val entry) target)]
175 (apply f (key entry) target args)))
177 (defn add-context-observer
178 "Observer registered with this function will be automatically
179 removed after the next frame rendering is complete."
180 [target f]
181 (let [root *root*]
182 (add-observer root target f)))
184 (defn repaint-on-update
185 "Trigger repaint of the current scene when the target updates."
186 [target]
187 (let [root *root*]
188 (if (not= root target)
189 (add-observer root target (fn [w _] (update w))))))
191 (defn repaint
192 "Repaint the current scene."
193 []
194 (update *root*))
196 ;;
197 ;; Rendering
198 ;;
200 (defn- relative-transform
201 "AffineTransform: layer context -> awt component."
202 []
203 (let [tr (.getTransform *graphics*)]
204 (.preConcatenate tr *inverse-initial-transform*)
205 tr))
207 (defn- inverse-relative-transform
208 "AffineTransform: awt component -> layer context."
209 []
210 (let [tr (.getTransform *graphics*)]
211 (.invert tr) ; absolute -> layer
212 (.concatenate tr *initial-transform*) ; component -> absolute
213 tr))
215 (defn- clip
216 "Intersect clipping area with the specified shape or bounds.
217 Returns new clip (Shape or nil if empty)."
218 ([x y w h]
219 (clip (Rectangle2D$Double. x y w h)))
220 ([shape]
221 (let [a1 (Area. shape)
222 a2 (if (instance? Area *clip*) *clip* (Area. *clip*))]
223 (.transform a1 (relative-transform))
224 (.intersect a1 a2)
225 (if (.isEmpty a1)
226 nil
227 a1))))
229 (defn- ^Graphics2D apply-theme
230 "Set graphics' color and font to match theme.
231 Modifies and returns the first argument."
232 ([]
233 (apply-theme *graphics* *theme*))
234 ([^Graphics2D graphics theme]
235 (doto graphics
236 (.setColor (:fore-color theme))
237 (.setFont (:font theme)))))
239 (defn- ^Graphics2D create-graphics
240 ([]
241 (create-graphics 0 0 *width* *height*))
242 ([x y w h]
243 (apply-theme (.create *graphics* x y w h) *theme*)))
245 (defn with-bounds*
246 [x y w h f & args]
247 (when-let [clip (clip x y w h)]
248 (let [graphics (create-graphics x y w h)]
249 (try
250 (binding [*width* w
251 *height* h
252 *clip* clip
253 *graphics* graphics]
254 (apply f args))
255 (finally
256 (.dispose graphics))))))
258 (defmacro with-bounds
259 [x y w h & body]
260 `(with-bounds* ~x ~y ~w ~h (fn [] ~@body)))
262 (defmacro with-theme
263 [theme & body]
264 `(binding [*theme* (merge *theme* ~theme)]
265 ~@body))
267 (defmacro with-color
268 [color-or-keyword & body]
269 (let [color-form (if (keyword? color-or-keyword)
270 `(~color-or-keyword *theme*)
271 color-or-keyword)]
272 `(let [color# ~color-form
273 old-color# (.getColor *graphics*)]
274 (try
275 (.setColor *graphics* color#)
276 ~@body
277 (finally
278 (.setColor *graphics* old-color#))))))
280 ;; TODO: constructor for AffineTransform.
281 ;; (transform :scale 0.3 0.5
282 ;; :translate 5 10
283 ;; :rotate (/ Math/PI 2))
285 (defmacro with-transform [transform & body]
286 `(let [old-t# (.getTransform *graphics*)]
287 (try
288 (.transform *graphics* ~transform)
289 ~@body
290 (finally
291 (.setTransform *graphics* old-t#)))))
293 (defmacro with-rotate [theta ax ay & body]
294 `(let [transform# (AffineTransform/getRotateInstance ~theta ~ax ~ay)]
295 (with-transform transform# ~@body)))
297 (defn draw!
298 "Draws layer."
299 ([layer]
300 (let [graphics (create-graphics)]
301 (try
302 (binding [*graphics* graphics]
303 (render! layer))
304 (finally
305 (.dispose graphics)))))
306 ([layer x y]
307 (let [size (layer-size layer)]
308 (draw! layer x y (:width size) (:height size))))
309 ([layer x y width height]
310 (with-bounds* x y width height render! layer)))
312 (defn draw-anchored!
313 "Draws layer. Location is relative to the layer's anchor point for
314 the specified alignment."
315 ([layer h-align v-align x y]
316 (let [anchor (anchor layer h-align v-align)]
317 (draw! layer (- x (:x anchor)) (- y (:y anchor)))))
318 ([layer h-align v-align x y w h]
319 (let [anchor (anchor layer h-align v-align)]
320 (draw! layer (- x (:x anchor)) (- y (:y anchor)) w h))))
322 (defn draw-root!
323 "Draws the root layer."
324 ([layer graphics width height event-dispatcher]
325 (draw-root! layer graphics width height event-dispatcher nil))
326 ([layer ^Graphics2D graphics width height event-dispatcher target]
327 (binding [*root* layer
328 *target* target
329 *graphics* graphics
330 *font-context* (.getFontRenderContext graphics)
331 *initial-transform* (.getTransform graphics)
332 *inverse-initial-transform*
333 (-> graphics .getTransform .createInverse)
334 *event-dispatcher* event-dispatcher
335 *width* width
336 *height* height
337 *clip* (Rectangle2D$Double. 0 0 width height)
338 *time* (System/nanoTime)]
339 ;; (.setRenderingHint graphics
340 ;; RenderingHints/KEY_INTERPOLATION
341 ;; RenderingHints/VALUE_INTERPOLATION_BILINEAR)
342 ;; (.setRenderingHint graphics
343 ;; RenderingHints/KEY_ALPHA_INTERPOLATION
344 ;; RenderingHints/VALUE_ALPHA_INTERPOLATION_QUALITY)
345 ;; (.setRenderingHint graphics
346 ;; RenderingHints/KEY_ANTIALIASING
347 ;; RenderingHints/VALUE_ANTIALIAS_ON)
348 (apply-theme)
349 (with-color (:back-color *theme*)
350 (.fillRect graphics 0 0 width height))
351 (let [tmp-watcher (Object.)]
352 ;; Keep current context observers until the rendering is
353 ;; complete. Some observers may be invoked twice if they
354 ;; appear in both groups until tmp-watcher is removed.
355 (replace-observers-watcher layer tmp-watcher)
356 (try
357 (render! layer)
358 (finally
359 (remove-observers tmp-watcher)
360 (commit event-dispatcher)))))))
362 (defn root-size
363 ([layer font-context]
364 (root-size layer font-context nil))
365 ([layer font-context target]
366 (binding [*root* layer
367 *target* target
368 *font-context* font-context]
369 (layer-size layer))))
371 ;;
372 ;; Event handling.
373 ;;
375 (defn with-handlers*
376 [handle handlers f & args]
377 (binding [*event-dispatcher* (create-dispatcher
378 *event-dispatcher* handle handlers)]
379 (apply f args)))
381 (defmacro with-handlers
382 "specs => (:event-id name & handler-body)*
384 Execute form with the specified event handlers."
385 [handle form & specs]
386 `(with-handlers* ~handle
387 ~(reduce (fn [m spec]
388 (assoc m (first spec)
389 `(fn [~(second spec)]
390 ~@(nnext spec)))) {}
391 specs)
392 (fn [] ~form)))
394 (defn picked? [handle]
395 (handle-picked? *event-dispatcher* handle))
397 (defn hovered? [handle]
398 (handle-hovered? *event-dispatcher* handle))
401 ;;
402 ;; EventDispatcher implementation
403 ;;
405 (def awt-events
406 {java.awt.event.MouseEvent/MOUSE_CLICKED :mouse-clicked
407 java.awt.event.MouseEvent/MOUSE_DRAGGED :mouse-dragged
408 java.awt.event.MouseEvent/MOUSE_ENTERED :mouse-entered
409 java.awt.event.MouseEvent/MOUSE_EXITED :mouse-exited
410 java.awt.event.MouseEvent/MOUSE_MOVED :mouse-moved
411 java.awt.event.MouseEvent/MOUSE_PRESSED :mouse-pressed
412 java.awt.event.MouseEvent/MOUSE_RELEASED :mouse-released})
414 (def dummy-event-dispatcher
415 (reify
416 EventDispatcher
417 (listen! [this component])
418 (create-dispatcher [this handle handlers] this)
419 (commit [this])
420 (handle-picked? [this handle])
421 (handle-hovered? [this handle])))
423 (defrecord DispatcherNode [handle handlers parent
424 ^Shape clip ^AffineTransform transform
425 bindings]
426 EventDispatcher
427 (listen! [this component]
428 (listen! parent component))
429 (create-dispatcher [this handle handlers]
430 (create-dispatcher parent handle handlers))
431 (commit [this]
432 (commit parent))
433 (handle-picked? [this handle]
434 (handle-picked? parent handle))
435 (handle-hovered? [this handle]
436 (handle-hovered? parent handle)))
438 (defn- make-node [handle handlers]
439 (DispatcherNode. handle handlers *event-dispatcher* *clip*
440 (inverse-relative-transform)
441 (get-thread-bindings)))
443 (defn- add-node [tree node]
444 (assoc-cons tree (:parent node) node))
446 (defn- under-cursor
447 "Returns a vector of child nodes under cursor."
448 [x y tree node]
449 (some #(if (.contains ^Shape (:clip %) x y)
450 (conj (vec (under-cursor x y tree %)) %))
451 (get tree node)))
453 (defn- remove-all [coll1 coll2 pred]
454 (filter #(not (some (partial pred %) coll2)) coll1))
456 (defn- transform [^AffineTransform tr x y]
457 (let [p (Point2D$Double. x y)]
458 (.transform tr p p)
459 [(.x p) (.y p)]))
461 (defn- translate-mouse-event [^java.awt.event.MouseEvent event
462 ^AffineTransform tr id]
463 (let [[x y] (transform tr (.getX event) (.getY event))]
464 (MouseEvent. id (.getWhen event) x y
465 (.getXOnScreen event) (.getYOnScreen event)
466 (.getButton event))))
468 (defn- translate-and-dispatch
469 ([nodes first-only ^java.awt.event.MouseEvent event]
470 (translate-and-dispatch nodes first-only
471 event (awt-events (.getID event))))
472 ([nodes first-only event id]
473 (if-let [node (first nodes)]
474 (if-let [handler (get (:handlers node) id)]
475 (do
476 (with-bindings* (:bindings node)
477 handler
478 (translate-mouse-event event (:transform node) id))
479 (if-not first-only
480 (recur (rest nodes) false event id)))
481 (recur (rest nodes) first-only event id)))))
483 (defn- dispatch-mouse-motion
484 "Dispatches mouse motion events."
485 [hovered-ref tree root ^java.awt.event.MouseEvent event]
486 (let [x (.getX event)
487 y (.getY event)
488 [hovered hovered2] (dosync
489 [@hovered-ref
490 (ref-set hovered-ref
491 (under-cursor x y tree root))])
492 pred #(= (:handle %1) (:handle %2))
493 exited (remove-all hovered hovered2 pred)
494 entered (remove-all hovered2 hovered pred)
495 moved (remove-all hovered2 entered pred)]
496 (translate-and-dispatch exited false event :mouse-exited)
497 (translate-and-dispatch entered false event :mouse-entered)
498 (translate-and-dispatch moved true event :mouse-moved)))
500 (defn- dispatch-mouse-button
501 [picked-ref hovered-ref ^java.awt.event.MouseEvent event]
502 (let [id (awt-events (.getID event))
503 nodes (case id
504 :mouse-pressed
505 (dosync
506 (ref-set picked-ref @hovered-ref))
507 :mouse-released
508 (dosync
509 (let [picked @picked-ref]
510 (ref-set picked-ref nil)
511 picked))
512 @hovered-ref)]
513 (translate-and-dispatch nodes true event id)))
515 (defn root-event-dispatcher []
516 (let [tree-r (ref {}) ; register
517 tree (ref {}) ; dispatch
518 hovered (ref '())
519 picked (ref '())]
520 (reify
521 EventDispatcher
522 (listen! [this component]
523 (doto component
524 (.addMouseListener this)
525 (.addMouseMotionListener this)))
526 (create-dispatcher [this handle handlers]
527 (let [node (make-node handle handlers)]
528 (dosync (alter tree-r add-node node))
529 node))
530 (commit [this]
531 (dosync (ref-set tree @tree-r)
532 (ref-set tree-r {})))
533 (handle-picked? [this handle]
534 (some #(= handle (:handle %)) @picked))
535 (handle-hovered? [this handle]
536 (some #(= handle (:handle %)) @hovered))
537 MouseListener
538 (mouseEntered [this event]
539 (dispatch-mouse-motion hovered @tree this event))
540 (mouseExited [this event]
541 (dispatch-mouse-motion hovered @tree this event))
542 (mouseClicked [this event]
543 (dispatch-mouse-button picked hovered event))
544 (mousePressed [this event]
545 (dispatch-mouse-button picked hovered event))
546 (mouseReleased [this event]
547 (dispatch-mouse-button picked hovered event))
548 MouseMotionListener
549 (mouseDragged [this event]
550 (translate-and-dispatch @picked true event))
551 (mouseMoved [this event]
552 (dispatch-mouse-motion hovered @tree this event)))))