Mercurial > hg > indyvon
view src/net/kryshen/indyvon/core.clj @ 148:613bd4ac1bc0
Panel has background color argument.
| author | Mikhail Kryshen <mikhail@kryshen.net> |
|---|---|
| date | Thu, 25 Apr 2013 04:01:33 +0400 |
| parents | dc437b4ceeea |
| children | cb108c6fa079 |
line source
1 ;;
2 ;; Copyright 2010, 2011, 2012, 2013 Mikhail Kryshen <mikhail@kryshen.net>
3 ;;
4 ;; This file is part of Indyvon.
5 ;;
6 ;; Indyvon is free software: you can redistribute it and/or modify it
7 ;; under the terms of the GNU Lesser General Public License version 3
8 ;; only, as published by the Free Software Foundation.
9 ;;
10 ;; Indyvon is distributed in the hope that it will be useful, but
11 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 ;; Lesser General Public License for more details.
14 ;;
15 ;; You should have received a copy of the GNU Lesser General Public
16 ;; License along with Indyvon. If not, see
17 ;; <http://www.gnu.org/licenses/>.
18 ;;
20 (ns net.kryshen.indyvon.core
21 (:import
22 (java.awt Graphics2D RenderingHints Component Color Font Shape
23 Rectangle Cursor EventQueue)
24 (java.awt.geom AffineTransform Point2D$Double Rectangle2D$Double Area)
25 (java.awt.event MouseListener MouseMotionListener
26 MouseWheelListener MouseWheelEvent)
27 (java.awt.font FontRenderContext)
28 java.util.concurrent.ConcurrentMap
29 com.google.common.collect.MapMaker))
31 ;;
32 ;; Layer context
33 ;;
35 (def ^:dynamic ^Graphics2D *graphics*)
37 (def ^:dynamic ^FontRenderContext *font-context*
38 "FontRenderContext to use when Graphics2D is not available."
39 (FontRenderContext.
40 nil
41 RenderingHints/VALUE_TEXT_ANTIALIAS_DEFAULT
42 RenderingHints/VALUE_FRACTIONALMETRICS_DEFAULT))
44 (def ^:dynamic *width*
45 "Width of the rendering area.")
47 (def ^:dynamic *height*
48 "Height of the rendering area.")
50 (def ^:dynamic ^Shape *clip*)
52 (def ^:dynamic ^Shape *input-clip*
53 "Clipping area used for dispatching pointer events (intersected with
54 *clip*). If nil, *clip* will be used.")
56 (def ^:dynamic *time*
57 "Timestamp of the current frame (in nanoseconds).")
59 (def ^:dynamic *scene*
60 "Encloses state that should be retained between repaints.")
62 (def ^:dynamic *states*
63 "Transient scene states, a map.")
65 (def ^:dynamic *event-dispatcher*)
67 (def ^:dynamic ^AffineTransform *initial-transform*
68 "Initial transform associated with the graphics context.")
70 (def ^:dynamic ^AffineTransform *inverse-initial-transform*
71 "Inversion of the initial transform associated with the graphics
72 context.")
74 (defrecord Theme [fore-color back-color alt-back-color border-color
75 shadow-color font])
77 ;; REMIND: use system colors, see java.awt.SystemColor.
78 (defn default-theme []
79 (Theme. Color/BLACK
80 Color/WHITE
81 (Color. 0xDD 0xDD 0xDD)
82 (Color. 0 0 0xCC)
83 (Color. 0x44 0x44 0x44)
84 (Font. "Sans" Font/PLAIN 12)))
86 (def ^:dynamic *theme* (default-theme))
88 ;;
89 ;; Core protocols and types
90 ;;
92 (defprotocol Layer
93 "Basic UI element."
94 (render! [layer]
95 "Draws layer in the current *graphics* context.")
96 (geometry [layer]
97 "Returns the preferred layer Geometry."))
99 (defprotocol Geometry
100 "Describes geometry of a Layer. Prefer using the available
101 implementations (Size, FixedGeometry and NestedGeometry) over
102 extending this protocol directly as it is likely to be changed in
103 the future versions."
104 (width [geom] [geom height])
105 (height [geom] [geom width])
106 (anchor-x [geom h-align width]
107 "Returns the x coordinate of the anchor point for the specified
108 horizontal alignment and width, h-align could be :left, :center
109 or :right.")
110 (anchor-y [geom v-align height]
111 "Returns the y coordinate of the anchor point for the specified
112 vertical alignment and height, v-align could be :top, :center
113 or :bottom."))
115 (defn- emit-align-xy [align size first center last]
116 `(case ~align
117 ~first 0
118 ~center (/ ~size 2)
119 ~last ~size))
121 ;; Define as macro to avoid unnecessary calculation of width or height.
122 (defmacro align-x
123 ([align inner outer]
124 `(align-x ~align (- ~outer ~inner)))
125 ([align width]
126 (emit-align-xy align width :left :center :right)))
128 (defmacro align-y
129 ([align inner outer]
130 `(align-y ~align (- ~outer ~inner)))
131 ([align height]
132 (emit-align-xy align height :top :center :bottom)))
134 (defrecord Size [width height]
135 Geometry
136 (width [_] width)
137 (width [_ _] width)
138 (height [_] height)
139 (height [_ _] height)
140 (anchor-x [_ h-align width]
141 (align-x h-align width))
142 (anchor-y [_ v-align height]
143 (align-y v-align height)))
145 (defrecord FixedGeometry [ax ay width height]
146 Geometry
147 (width [_] width)
148 (width [_ _] width)
149 (height [_] height)
150 (height [_ _] height)
151 (anchor-x [_ _ _] ax)
152 (anchor-y [_ _ _] ay))
154 (defrecord NestedGeometry [geometry top left bottom right]
155 Geometry
156 (width [_]
157 (+ left right (width geometry)))
158 (width [_ h]
159 (+ left right (width geometry (- h top bottom))))
160 (height [_]
161 (+ top bottom (height geometry)))
162 (height [_ w]
163 (+ top bottom (height geometry (- w left right))))
164 (anchor-x [_ h-align w]
165 (+ left (anchor-x geometry h-align (- w left right))))
166 (anchor-y [_ v-align h]
167 (+ top (anchor-y geometry v-align (- h top bottom)))))
169 (defrecord ScaledGeometry [geometry sx sy]
170 Geometry
171 (width [_]
172 (* sx (width geometry)))
173 (width [_ h]
174 (* sx (width geometry (/ h sy))))
175 (height [_]
176 (* sy (height geometry)))
177 (height [_ w]
178 (* sy (height geometry (/ w sx))))
179 (anchor-x [_ h-align w]
180 (* sx (anchor-x geometry h-align (/ w sx))))
181 (anchor-y [_ v-align h]
182 (* sy (anchor-y geometry v-align (/ h sy)))))
184 ;; (defn ^:private to-integer
185 ;; ^long [align x]
186 ;; (if (integer? x)
187 ;; x
188 ;; (let [x (double x)]
189 ;; (Math/round
190 ;; (case align
191 ;; (:top :left) (Math/floor x)
192 ;; :center x
193 ;; (:bottom :right) (Math/ceil x))))))
195 ;; (defrecord IntegerGeometry [geometry]
196 ;; Geometry
197 ;; (width [_]
198 ;; (to-integer :right (width geometry)))
199 ;; (width [_ h]
200 ;; (to-integer :right (width geometry h)))
201 ;; (height [_]
202 ;; (to-integer :bottom (height geometry)))
203 ;; (height [_ w]
204 ;; (to-integer :bottom (height geometry w)))
205 ;; (anchor-x [_ h-align w]
206 ;; (to-integer h-align (anchor-x geometry h-align w)))
207 ;; (anchor-y [_ v-align h]
208 ;; (to-integer v-align (anchor-y geometry v-align h))))
210 ;; TODO: modifiers
211 (defrecord MouseEvent [id when x y x-on-screen y-on-screen button
212 wheel-rotation transform component])
214 ;; TODO: KeyEvent
216 (defprotocol EventDispatcher
217 (listen! [this component]
218 "Listen for events on the specified AWT Component.")
219 (create-dispatcher [this handle handlers]
220 "Returns new event dispatcher associated with the specified event
221 handlers (an event-id -> handler-fn map). Handle is used to
222 match the contexts between commits.")
223 (commit [this]
224 "Apply the registered handlers for event processing.")
225 (handle-picked? [this handle]
226 "Returns true if the specified handle received the :mouse-pressed
227 event and have not yet received :moused-released.")
228 (handle-hovered? [this handle]
229 "Returns true if the specified handle received the :mouse-entered
230 event and have not yet received :mouse-exited."))
232 (defn- assoc-cons [m key val]
233 (->> (get m key) (cons val) (assoc m key)))
235 ;;
236 ;; Observers
237 ;; The mechanism used by layers to request repaints
238 ;;
240 (def ^ConcurrentMap observers
241 (-> (MapMaker.) (.weakKeys) (.makeMap)))
243 (defn- cm-replace!
244 "Wrap ConcurrentMap replace method to treat nil value as absent
245 mapping. Use with maps that does not support nil values."
246 [^ConcurrentMap cmap key old new]
247 (if (nil? old)
248 (nil? (.putIfAbsent cmap key new))
249 (.replace cmap key old new)))
251 (defn- cm-swap!
252 "Atomically swaps the value associated with key in ConcurrentMap
253 to be (apply f current-value args). Returns the new value."
254 [^ConcurrentMap cmap key f & args]
255 (loop []
256 (let [old (.get cmap key)
257 new (apply f old args)]
258 (if (cm-replace! cmap key old new)
259 new
260 (recur)))))
262 (defn add-observer
263 "Add observer fn for the target. Watcher identifies the group of
264 observers and could be used to remove the group. Watcher is weakly
265 referenced, all associated observers will be removed when the
266 wathcer is removed by gc. The observer fn will be called with
267 watcher and target arguments and any additional arguments specified
268 in update call."
269 [watcher target f]
270 (cm-swap! observers watcher assoc-cons target f)
271 nil)
273 (defn remove-observers
274 "Remove group of observers associated with the specified watcher."
275 [watcher]
276 (.remove observers watcher)
277 nil)
279 (defn- replace-observers-watcher
280 [old-watcher new-watcher]
281 (if-let [old (.remove observers old-watcher)]
282 (.put observers new-watcher old))
283 nil)
285 (defn update
286 "Notify observers."
287 [target & args]
288 (doseq [entry observers
289 f (get (val entry) target)]
290 (apply f (key entry) target args)))
292 (defn add-context-observer
293 "Observer registered with this function will be automatically
294 removed after the next repaint is complete."
295 [target f]
296 (add-observer *scene* target f))
298 (defn repaint-on-update
299 "Trigger repaint of the current scene when the target updates."
300 [target]
301 (let [scene *scene*]
302 (if-not (identical? scene target)
303 (add-observer scene target (fn [w _] (update w))))))
305 (defn repaint
306 "Requests repaint of the current scene. If handle and state are
307 specified, the handle will be associated with the state in the
308 *states* map for the next paint iteration."
309 ([]
310 (update *scene*))
311 ([handle state]
312 (let [scene *scene*]
313 (swap! (:next-state scene) assoc handle state)
314 (update scene))))
316 ;;
317 ;; Rendering
318 ;;
320 (defn ^FontRenderContext font-context
321 "Returns FontRenderContext for the current Layer context."
322 []
323 (if (bound? (var *graphics*))
324 (.getFontRenderContext *graphics*)
325 *font-context*))
327 (defn ^AffineTransform relative-transform
328 "Returns AffineTransform: layer context -> AWT component."
329 []
330 (let [tr (.getTransform *graphics*)]
331 (.preConcatenate tr *inverse-initial-transform*)
332 tr))
334 (defn ^AffineTransform inverse-relative-transform
335 "Returns AffineTransform: AWT component -> layer context."
336 []
337 (let [tr (.getTransform *graphics*)]
338 (.invert tr) ; absolute -> layer
339 (.concatenate tr *initial-transform*) ; component -> absolute
340 tr))
342 (defn transform-point [^AffineTransform tr ^double x ^double y]
343 (let [p (Point2D$Double. x y)]
344 (.transform tr p p)
345 [(.x p) (.y p)]))
347 (defn inverse-transform-point [^AffineTransform tr ^double x ^double y]
348 (let [p (Point2D$Double. x y)]
349 (.inverseTransform tr p p)
350 [(.x p) (.y p)]))
352 ;; (defn- clip
353 ;; "Intersect clipping area with the specified shape or bounds.
354 ;; Returns new clip (Shape or nil if empty)."
355 ;; ([x y w h]
356 ;; (clip (Rectangle2D$Double. x y w h)))
357 ;; ([shape]
358 ;; (let [a1 (Area. shape)
359 ;; a2 (if (instance? Area *clip*) *clip* (Area. *clip*))]
360 ;; (.transform a1 (relative-transform))
361 ;; (.intersect a1 a2)
362 ;; (if (.isEmpty a1)
363 ;; nil
364 ;; a1))))
366 ;; Use faster clipping calculation provided by Graphics2D.
367 (defn- clip
368 "Intersect clipping area with the specified Shape in current
369 transform coordinates. Returns new clip in the AWT component
370 coordinates (Shape or nil if empty)."
371 [^Shape shape]
372 (let [^Graphics2D clip-g (.create *graphics*)]
373 (try
374 (doto clip-g
375 (.setClip shape)
376 (.setTransform *initial-transform*)
377 (.clip *clip*))
378 (if (.isEmpty (.getClipBounds clip-g))
379 nil
380 (.getClip clip-g))
381 (finally
382 (.dispose clip-g)))))
384 (defn- ^Graphics2D apply-theme
385 "Set graphics' color and font to match theme.
386 Modifies and returns the first argument."
387 ([]
388 (apply-theme *graphics* *theme*))
389 ([^Graphics2D graphics theme]
390 (doto graphics
391 (.setColor (:fore-color theme))
392 (.setFont (:font theme)))))
394 (defn- ^Graphics2D create-graphics
395 ([]
396 (apply-theme (.create *graphics*) *theme*))
397 ([^long x ^long y ^long w ^long h]
398 (apply-theme (.create *graphics* x y w h) *theme*)))
400 (defn- with-bounds-noclip*
401 [x y w h f & args]
402 (let [graphics (create-graphics)]
403 (try
404 (.translate graphics (double x) (double y))
405 (binding [*width* w
406 *height* h
407 *input-clip* (Rectangle2D$Double. 0.0 0.0 w h)
408 *graphics* graphics]
409 (apply f args))
410 (finally
411 (.dispose graphics)))))
413 (defn with-bounds*
414 [x y w h f & args]
415 (let [x (double x)
416 y (double y)
417 bounds (Rectangle2D$Double. x y w h)]
418 (when-let [clip (clip bounds)]
419 (let [^Graphics2D graphics (create-graphics)]
420 (try
421 (.clip graphics bounds)
422 (.translate graphics x y)
423 (binding [*width* w
424 *height* h
425 *clip* clip
426 *input-clip* nil
427 *graphics* graphics]
428 (apply f args))
429 (finally
430 (.dispose graphics)))))))
432 (defmacro with-bounds
433 [x y w h & body]
434 `(with-bounds* ~x ~y ~w ~h (fn [] ~@body)))
436 (defmacro with-theme
437 [theme & body]
438 `(binding [*theme* (merge *theme* ~theme)]
439 ~@body))
441 (defmacro with-color [color-or-key & body]
442 `(let [color# ~color-or-key
443 color# (get *theme* color# color#)
444 g# *graphics*
445 old-color# (.getColor g#)]
446 (try
447 (.setColor g# color#)
448 ~@body
449 (finally
450 (.setColor g# old-color#)))))
452 (defmacro with-stroke [stroke & body]
453 `(let [g# *graphics*
454 old-stroke# (.getStroke g#)]
455 (try
456 (.setStroke g# ~stroke)
457 ~@body
458 (finally
459 (.setStroke g# old-stroke#)))))
461 (defmacro with-hints
462 [hints & body]
463 `(let [h# ~hints
464 g# *graphics*
465 old# (.getRenderingHints g#)]
466 (try
467 (.addRenderingHints g# h#)
468 ~@body
469 (finally
470 (.setRenderingHints g# old#)))))
472 (defn with-hints* [hints f & args]
473 (with-hints hints
474 (apply f args)))
476 ;; TODO: constructor for AffineTransform.
477 ;; (transform :scale 0.3 0.5
478 ;; :translate 5 10
479 ;; :rotate (/ Math/PI 2))
481 (defmacro with-transform [transform & body]
482 `(let [g# *graphics*
483 old-t# (.getTransform g#)]
484 (try
485 (.transform g# ~transform)
486 ~@body
487 (finally
488 (.setTransform g# old-t#)))))
490 (defmacro with-rotate [theta ax ay & body]
491 `(let [transform# (AffineTransform/getRotateInstance ~theta ~ax ~ay)]
492 (with-transform transform# ~@body)))
494 (defmacro with-translate [x y & body]
495 `(let [x# ~x
496 y# ~y
497 g# *graphics*]
498 (try
499 (.translate g# x# y#)
500 ~@body
501 (finally
502 (.translate g# (- x#) (- y#))))))
504 (defn draw!
505 "Draws layer."
506 ([layer]
507 (let [graphics (create-graphics)]
508 (try
509 (binding [*graphics* graphics]
510 (render! layer))
511 (finally
512 (.dispose graphics)))))
513 ([layer x y]
514 (draw! layer x y true))
515 ([layer x y clip?]
516 (let [geom (geometry layer)]
517 (draw! layer x y (width geom) (height geom) clip?)))
518 ([layer x y width height]
519 (draw! layer x y width height true))
520 ([layer x y width height clip?]
521 (if clip?
522 (with-bounds* x y width height render! layer)
523 (with-bounds-noclip* x y width height render! layer))))
525 (defn draw-aligned!
526 "Draws layer. Location is relative to the layer's anchor point for
527 the specified alignment."
528 ([layer h-align v-align x y]
529 (let [geom (geometry layer)
530 w (width geom)
531 h (height geom)]
532 (draw! layer
533 (- x (anchor-x geom h-align w))
534 (- y (anchor-y geom v-align h))
535 w h)))
536 ([layer h-align v-align x y w h]
537 (let [geom (geometry layer)]
538 (draw! layer
539 (- x (anchor-x geom h-align w))
540 (- y (anchor-y geom v-align h))
541 w h))))
543 ;;
544 ;; Event handling.
545 ;;
547 (defn with-handlers*
548 [handle handlers f & args]
549 (binding [*event-dispatcher* (create-dispatcher
550 *event-dispatcher* handle handlers)]
551 (apply f args)))
553 (defmacro with-handlers
554 "specs => (:event-id name & handler-body)*
556 Execute form with the specified event handlers."
557 [handle form & specs]
558 `(with-handlers* ~handle
559 ~(reduce (fn [m spec]
560 (assoc m (first spec)
561 `(fn [~(second spec)]
562 ~@(nnext spec)))) {}
563 specs)
564 (fn [] ~form)))
566 (defn picked? [handle]
567 (handle-picked? *event-dispatcher* handle))
569 (defn hovered? [handle]
570 (handle-hovered? *event-dispatcher* handle))
572 ;;
573 ;; EventDispatcher implementation
574 ;;
576 (def awt-events
577 {java.awt.event.MouseEvent/MOUSE_CLICKED :mouse-clicked
578 java.awt.event.MouseEvent/MOUSE_DRAGGED :mouse-dragged
579 java.awt.event.MouseEvent/MOUSE_ENTERED :mouse-entered
580 java.awt.event.MouseEvent/MOUSE_EXITED :mouse-exited
581 java.awt.event.MouseEvent/MOUSE_MOVED :mouse-moved
582 java.awt.event.MouseEvent/MOUSE_PRESSED :mouse-pressed
583 java.awt.event.MouseEvent/MOUSE_RELEASED :mouse-released
584 java.awt.event.MouseEvent/MOUSE_WHEEL :mouse-wheel})
586 (def dummy-event-dispatcher
587 (reify EventDispatcher
588 (listen! [_ _])
589 (create-dispatcher [this _ _] this)
590 (commit [_])
591 (handle-picked? [_ _])
592 (handle-hovered? [_ _])))
594 ;; Not using defrecord to avoid unacceptable overhead of recursive
595 ;; hash code calculation.
596 (deftype DispatcherNode [handle handlers parent
597 ^Shape clip ^AffineTransform transform
598 bindings]
599 EventDispatcher
600 (listen! [this component]
601 (listen! parent component))
602 (create-dispatcher [this handle handlers]
603 (create-dispatcher parent handle handlers))
604 (commit [this]
605 (commit parent))
606 (handle-picked? [this handle]
607 (handle-picked? parent handle))
608 (handle-hovered? [this handle]
609 (handle-hovered? parent handle)))
611 (defn- make-node [handle handlers]
612 (let [clip (if *input-clip*
613 (clip *input-clip*)
614 *clip*)
615 bindings (-> (get-thread-bindings)
616 (dissoc (var *graphics*))
617 (assoc (var *font-context*) (font-context)))]
618 (DispatcherNode. handle handlers *event-dispatcher* clip
619 (relative-transform)
620 bindings)))
622 (defn- add-node [tree ^DispatcherNode node]
623 (assoc-cons tree (.parent node) node))
625 (defn- nodes [tree]
626 (apply concat (vals tree)))
628 (defn- under-cursor
629 "Returns a vector of child nodes under cursor."
630 [node tree ^long x ^long y]
631 (some (fn [^DispatcherNode n]
632 (if (and (.clip n) (.contains ^Shape (.clip n) x y))
633 (conj (vec (under-cursor n tree x y)) n)))
634 (get tree node)))
636 (defn- translate-mouse-event [^java.awt.event.MouseEvent event
637 ^AffineTransform tr id]
638 (let [[x y] (inverse-transform-point tr (.getX event) (.getY event))
639 rotation (if (instance? MouseWheelEvent event)
640 (.getWheelRotation ^MouseWheelEvent event)
641 nil)]
642 (->MouseEvent id (.getWhen event) x y
643 (.getXOnScreen event) (.getYOnScreen event)
644 (.getButton event)
645 rotation
646 tr
647 (.getComponent event))))
649 (defn- translate-and-dispatch
650 ([nodes first-only ^java.awt.event.MouseEvent event]
651 (translate-and-dispatch nodes first-only
652 event (awt-events (.getID event))))
653 ([nodes first-only event id]
654 (if-let [^DispatcherNode node (first nodes)]
655 (let [handlers (.handlers node)
656 handler (get handlers id)]
657 (if handler
658 (do
659 (with-bindings* (.bindings node)
660 handler
661 (translate-mouse-event event (.transform node) id))
662 (when-not first-only
663 (recur (rest nodes) false event id)))
664 (when-not (and (= id :mouse-dragged)
665 (or (contains? handlers :mouse-pressed)
666 (contains? handlers :mouse-released)))
667 (recur (rest nodes) first-only event id)))))))
669 (defn- process-mouse-event
670 [dispatcher ^java.awt.event.MouseEvent source-event]
671 (let [{active-ref :active
672 hovered-ref :hovered
673 picked-ref :picked
674 last-ref :last-motion
675 tree-ref :tree} dispatcher
676 pressed (and source-event
677 (== (.getID source-event)
678 java.awt.event.MouseEvent/MOUSE_PRESSED))
679 released (and source-event
680 (== (.getID source-event)
681 java.awt.event.MouseEvent/MOUSE_RELEASED))
682 ^java.awt.event.MouseEvent last-event @last-ref
683 ^java.awt.event.MouseEvent event (or source-event last-event)]
684 (when event
685 (let [x (.getX event)
686 y (.getY event)
687 active @active-ref
688 active (if (and active
689 source-event
690 (== (.getX last-event) x)
691 (== (.getY last-event) y))
692 active
693 (ref-set active-ref
694 (under-cursor dispatcher @tree-ref x y)))
695 acted (cond
696 pressed (ref-set picked-ref active)
697 released (let [picked @picked-ref]
698 (ref-set picked-ref nil)
699 picked)
700 :else active)
701 picked (seq @picked-ref)
702 pred #(= (.handle ^DispatcherNode %1) (.handle ^DispatcherNode %2))
703 hovered (if picked
704 (filter #(some (partial pred %) picked) active)
705 active)
706 remove-all (fn [c1 c2]
707 (filter #(not (some (partial pred %) c2)) c1))
708 old-hovered @hovered-ref
709 exited (remove-all old-hovered hovered)
710 entered (remove-all hovered old-hovered)
711 moved (or picked (remove-all hovered entered))]
712 (ref-set hovered-ref hovered)
713 (ref-set last-ref event)
714 [exited entered moved acted event]))))
716 (defn- dispatch-mouse-event
717 [dispatcher source-event button?]
718 (when-let [[exited
719 entered
720 moved
721 acted
722 event] (dosync (process-mouse-event dispatcher source-event))]
723 (when button?
724 (translate-and-dispatch acted true event))
725 (translate-and-dispatch exited false event :mouse-exited)
726 (translate-and-dispatch entered false event :mouse-entered)
727 (when-not button?
728 (translate-and-dispatch moved true source-event))))
730 (defrecord RootEventDispatcher [tree-r ;; register
731 tree ;; dispatch
732 active ;; nodes under cursor
733 hovered ;; mouse entered
734 picked ;; mouse pressed
735 last-motion]
736 EventDispatcher
737 (listen! [dispatcher component]
738 (doto ^Component component
739 (.addMouseListener dispatcher)
740 (.addMouseWheelListener dispatcher)
741 (.addMouseMotionListener dispatcher)))
742 (create-dispatcher [dispatcher handle handlers]
743 (let [node (make-node handle handlers)]
744 (dosync (alter tree-r add-node node))
745 node))
746 (commit [dispatcher]
747 (let [[exited
748 entered
749 _ _
750 event] (dosync
751 ;; TODO: retain contexts that do
752 ;; not intersect graphics
753 ;; clipping area in tree.
754 (ref-set tree @tree-r)
755 (ref-set tree-r {})
756 (process-mouse-event dispatcher nil))]
757 ;; Send mouse entered and exited events if necessary due to
758 ;; updated layout.
759 (translate-and-dispatch exited false event :mouse-exited)
760 (translate-and-dispatch entered false event :mouse-entered)))
761 (handle-picked? [dispatcher handle]
762 (some #(= handle (.handle ^DispatcherNode %)) @picked))
763 (handle-hovered? [dispatcher handle]
764 (some #(= handle (.handle ^DispatcherNode %)) @hovered))
765 MouseListener
766 (mouseEntered [dispatcher event]
767 (dispatch-mouse-event dispatcher event false))
768 (mouseExited [dispatcher event]
769 (dispatch-mouse-event dispatcher event false))
770 (mouseClicked [dispatcher event]
771 (dispatch-mouse-event dispatcher event true))
772 (mousePressed [dispatcher event]
773 (dispatch-mouse-event dispatcher event true))
774 (mouseReleased [dispatcher event]
775 (dispatch-mouse-event dispatcher event true))
776 MouseWheelListener
777 (mouseWheelMoved [dispatcher event]
778 (dispatch-mouse-event dispatcher event true))
779 MouseMotionListener
780 (mouseDragged [dispatcher event]
781 (dispatch-mouse-event dispatcher event false))
782 (mouseMoved [dispatcher event]
783 (dispatch-mouse-event dispatcher event false)))
785 (defn root-event-dispatcher []
786 (->RootEventDispatcher
787 (ref {}) (ref {}) ;; trees
788 (ref nil) (ref nil) (ref nil) ;; node states
789 (ref nil))) ;; last event
791 ;;
792 ;; Scene
793 ;;
795 (defrecord Scene [layer
796 event-dispatcher
797 component
798 rendering-hints
799 next-state])
801 ;; Define rendering hints that affect font metrics to make sure that
802 ;; Graphics and Scene FontRenderContexts are consistent.
803 (def ^:private default-rendering-hints
804 {RenderingHints/KEY_TEXT_ANTIALIASING
805 RenderingHints/VALUE_TEXT_ANTIALIAS_DEFAULT,
806 RenderingHints/KEY_FRACTIONALMETRICS
807 RenderingHints/VALUE_FRACTIONALMETRICS_DEFAULT})
809 (defn make-scene
810 ([layer]
811 (make-scene layer dummy-event-dispatcher nil))
812 ([layer event-dispatcher]
813 (make-scene layer event-dispatcher nil))
814 ([layer event-dispatcher ^Component component]
815 (make-scene layer event-dispatcher component nil))
816 ([layer event-dispatcher ^Component component hints]
817 (let [hints (merge default-rendering-hints hints)]
818 (->Scene layer
819 event-dispatcher
820 component
821 hints
822 (atom nil)))))
824 (defn- get-and-set!
825 "Atomically sets the value of atom to newval and returns the old
826 value."
827 [atom newval]
828 (loop [v @atom]
829 (if (compare-and-set! atom v newval)
830 v
831 (recur @atom))))
833 (defn draw-scene!
834 [scene ^Graphics2D graphics width height]
835 (.addRenderingHints graphics (:rendering-hints scene))
836 (binding [*states* (get-and-set! (:next-state scene) nil)
837 *scene* scene
838 *graphics* graphics
839 *initial-transform* (.getTransform graphics)
840 *inverse-initial-transform* (-> graphics
841 .getTransform
842 .createInverse)
843 *event-dispatcher* (:event-dispatcher scene)
844 *width* width
845 *height* height
846 *clip* (Rectangle2D$Double. 0.0 0.0 width height)
847 *input-clip* nil
848 *time* (System/nanoTime)]
849 (apply-theme)
850 (let [tmp-watcher (Object.)]
851 ;; Keep current context observers until the rendering is
852 ;; complete. Some observers may be invoked twice if they
853 ;; appear in both groups until tmp-watcher is removed.
854 (replace-observers-watcher scene tmp-watcher)
855 (try
856 (render! (:layer scene))
857 (finally
858 (remove-observers tmp-watcher)
859 (commit (:event-dispatcher scene)))))))
861 (defn- scene-font-context [scene]
862 (let [hints (:rendering-hints scene)
863 ^Component c (:component scene)
864 t (if c (->> c
865 .getFont
866 (.getFontMetrics c)
867 .getFontRenderContext
868 .getTransform))]
869 (FontRenderContext.
870 t
871 (get hints RenderingHints/KEY_TEXT_ANTIALIASING)
872 (get hints RenderingHints/KEY_FRACTIONALMETRICS))))
874 (defn scene-geometry [scene]
875 (binding [*scene* scene
876 *font-context* (scene-font-context scene)]
877 (geometry (:layer scene))))
879 (defn set-cursor! [^Cursor cursor]
880 (when-let [^Component component (:component *scene*)]
881 (EventQueue/invokeLater #(.setCursor component cursor))))