Mercurial > hg > indyvon
view src/net/kryshen/indyvon/core.clj @ 146:dc437b4ceeea
Refactored align-x and align-y macros.
| author | Mikhail Kryshen <mikhail@kryshen.net> |
|---|---|
| date | Thu, 25 Apr 2013 02:41:50 +0400 |
| parents | 4dd98ea3b475 |
| children | 613bd4ac1bc0 |
line source
1 ;;
2 ;; Copyright 2010, 2011, 2012, 2013 Mikhail Kryshen <mikhail@kryshen.net>
3 ;;
4 ;; This file is part of Indyvon.
5 ;;
6 ;; Indyvon is free software: you can redistribute it and/or modify it
7 ;; under the terms of the GNU Lesser General Public License version 3
8 ;; only, as published by the Free Software Foundation.
9 ;;
10 ;; Indyvon is distributed in the hope that it will be useful, but
11 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 ;; Lesser General Public License for more details.
14 ;;
15 ;; You should have received a copy of the GNU Lesser General Public
16 ;; License along with Indyvon. If not, see
17 ;; <http://www.gnu.org/licenses/>.
18 ;;
20 (ns net.kryshen.indyvon.core
21 (:import
22 (java.awt Graphics2D RenderingHints Component Color Font Shape
23 Rectangle Cursor EventQueue)
24 (java.awt.geom AffineTransform Point2D$Double Rectangle2D$Double Area)
25 (java.awt.event MouseListener MouseMotionListener
26 MouseWheelListener MouseWheelEvent)
27 (java.awt.font FontRenderContext)
28 java.util.concurrent.ConcurrentMap
29 com.google.common.collect.MapMaker))
31 ;;
32 ;; Layer context
33 ;;
35 (def ^:dynamic ^Graphics2D *graphics*)
37 (def ^:dynamic ^FontRenderContext *font-context*
38 "FontRenderContext to use when Graphics2D is not available."
39 (FontRenderContext.
40 nil
41 RenderingHints/VALUE_TEXT_ANTIALIAS_DEFAULT
42 RenderingHints/VALUE_FRACTIONALMETRICS_DEFAULT))
44 (def ^:dynamic *width*
45 "Width of the rendering area.")
47 (def ^:dynamic *height*
48 "Height of the rendering area.")
50 (def ^:dynamic ^Shape *clip*)
52 (def ^:dynamic ^Shape *input-clip*
53 "Clipping area used for dispatching pointer events (intersected with
54 *clip*). If nil, *clip* will be used.")
56 (def ^:dynamic *time*
57 "Timestamp of the current frame (in nanoseconds).")
59 (def ^:dynamic *scene*
60 "Encloses state that should be retained between repaints.")
62 (def ^:dynamic *states*
63 "Transient scene states, a map.")
65 (def ^:dynamic *event-dispatcher*)
67 (def ^:dynamic ^AffineTransform *initial-transform*
68 "Initial transform associated with the graphics context.")
70 (def ^:dynamic ^AffineTransform *inverse-initial-transform*
71 "Inversion of the initial transform associated with the graphics
72 context.")
74 (defrecord Theme [fore-color back-color alt-back-color border-color
75 shadow-color font])
77 ;; REMIND: use system colors, see java.awt.SystemColor.
78 (defn default-theme []
79 (Theme. Color/BLACK
80 Color/WHITE
81 (Color. 0xDD 0xDD 0xDD)
82 (Color. 0 0 0xCC)
83 (Color. 0x44 0x44 0x44)
84 (Font. "Sans" Font/PLAIN 12)))
86 (def ^:dynamic *theme* (default-theme))
88 ;;
89 ;; Core protocols and types
90 ;;
92 (defprotocol Layer
93 "Basic UI element."
94 (render! [layer]
95 "Draws layer in the current *graphics* context.")
96 (geometry [layer]
97 "Returns the preferred layer Geometry."))
99 (defprotocol Geometry
100 "Describes geometry of a Layer. Prefer using the available
101 implementations (Size, FixedGeometry and NestedGeometry) over
102 extending this protocol directly as it is likely to be changed in
103 the future versions."
104 (width [geom] [geom height])
105 (height [geom] [geom width])
106 (anchor-x [geom h-align width]
107 "Returns the x coordinate of the anchor point for the specified
108 horizontal alignment and width, h-align could be :left, :center
109 or :right.")
110 (anchor-y [geom v-align height]
111 "Returns the y coordinate of the anchor point for the specified
112 vertical alignment and height, v-align could be :top, :center
113 or :bottom."))
115 (defn- emit-align-xy [align size first center last]
116 `(case ~align
117 ~first 0
118 ~center (/ ~size 2)
119 ~last ~size))
121 ;; Define as macro to avoid unnecessary calculation of width or height.
122 (defmacro align-x
123 ([align inner outer]
124 `(align-x ~align (- ~outer ~inner)))
125 ([align width]
126 (emit-align-xy align width :left :center :right)))
128 (defmacro align-y
129 ([align inner outer]
130 `(align-y ~align (- ~outer ~inner)))
131 ([align height]
132 (emit-align-xy align height :top :center :bottom)))
134 (defrecord Size [width height]
135 Geometry
136 (width [_] width)
137 (width [_ _] width)
138 (height [_] height)
139 (height [_ _] height)
140 (anchor-x [_ h-align width]
141 (align-x h-align width))
142 (anchor-y [_ v-align height]
143 (align-y v-align height)))
145 (defrecord FixedGeometry [ax ay width height]
146 Geometry
147 (width [_] width)
148 (width [_ _] width)
149 (height [_] height)
150 (height [_ _] height)
151 (anchor-x [_ _ _] ax)
152 (anchor-y [_ _ _] ay))
154 (defrecord NestedGeometry [geometry top left bottom right]
155 Geometry
156 (width [_]
157 (+ left right (width geometry)))
158 (width [_ h]
159 (+ left right (width geometry (- h top bottom))))
160 (height [_]
161 (+ top bottom (height geometry)))
162 (height [_ w]
163 (+ top bottom (height geometry (- w left right))))
164 (anchor-x [_ h-align w]
165 (+ left (anchor-x geometry h-align (- w left right))))
166 (anchor-y [_ v-align h]
167 (+ top (anchor-y geometry v-align (- h top bottom)))))
169 (defrecord ScaledGeometry [geometry sx sy]
170 Geometry
171 (width [_]
172 (* sx (width geometry)))
173 (width [_ h]
174 (* sx (width geometry (/ h sy))))
175 (height [_]
176 (* sy (height geometry)))
177 (height [_ w]
178 (* sy (height geometry (/ w sx))))
179 (anchor-x [_ h-align w]
180 (* sx (anchor-x geometry h-align (/ w sx))))
181 (anchor-y [_ v-align h]
182 (* sy (anchor-y geometry v-align (/ h sy)))))
184 ;; (defn ^:private to-integer
185 ;; ^long [align x]
186 ;; (if (integer? x)
187 ;; x
188 ;; (let [x (double x)]
189 ;; (Math/round
190 ;; (case align
191 ;; (:top :left) (Math/floor x)
192 ;; :center x
193 ;; (:bottom :right) (Math/ceil x))))))
195 ;; (defrecord IntegerGeometry [geometry]
196 ;; Geometry
197 ;; (width [_]
198 ;; (to-integer :right (width geometry)))
199 ;; (width [_ h]
200 ;; (to-integer :right (width geometry h)))
201 ;; (height [_]
202 ;; (to-integer :bottom (height geometry)))
203 ;; (height [_ w]
204 ;; (to-integer :bottom (height geometry w)))
205 ;; (anchor-x [_ h-align w]
206 ;; (to-integer h-align (anchor-x geometry h-align w)))
207 ;; (anchor-y [_ v-align h]
208 ;; (to-integer v-align (anchor-y geometry v-align h))))
210 ;; TODO: modifiers
211 (defrecord MouseEvent [id when x y x-on-screen y-on-screen button
212 wheel-rotation transform component])
214 ;; TODO: KeyEvent
216 (defprotocol EventDispatcher
217 (listen! [this component]
218 "Listen for events on the specified AWT Component.")
219 (create-dispatcher [this handle handlers]
220 "Returns new event dispatcher associated with the specified event
221 handlers (an event-id -> handler-fn map). Handle is used to
222 match the contexts between commits.")
223 (commit [this]
224 "Apply the registered handlers for event processing.")
225 (handle-picked? [this handle]
226 "Returns true if the specified handle received the :mouse-pressed
227 event and have not yet received :moused-released.")
228 (handle-hovered? [this handle]
229 "Returns true if the specified handle received the :mouse-entered
230 event and have not yet received :mouse-exited."))
232 (defn- assoc-cons [m key val]
233 (->> (get m key) (cons val) (assoc m key)))
235 ;;
236 ;; Observers
237 ;; The mechanism used by layers to request repaints
238 ;;
240 (def ^ConcurrentMap observers
241 (-> (MapMaker.) (.weakKeys) (.makeMap)))
243 (defn- cm-replace!
244 "Wrap ConcurrentMap replace method to treat nil value as absent
245 mapping. Use with maps that does not support nil values."
246 [^ConcurrentMap cmap key old new]
247 (if (nil? old)
248 (nil? (.putIfAbsent cmap key new))
249 (.replace cmap key old new)))
251 (defn- cm-swap!
252 "Atomically swaps the value associated with key in ConcurrentMap
253 to be (apply f current-value args). Returns the new value."
254 [^ConcurrentMap cmap key f & args]
255 (loop []
256 (let [old (.get cmap key)
257 new (apply f old args)]
258 (if (cm-replace! cmap key old new)
259 new
260 (recur)))))
262 (defn add-observer
263 "Add observer fn for the target. Watcher identifies the group of
264 observers and could be used to remove the group. Watcher is weakly
265 referenced, all associated observers will be removed when the
266 wathcer is removed by gc. The observer fn will be called with
267 watcher and target arguments and any additional arguments specified
268 in update call."
269 [watcher target f]
270 (cm-swap! observers watcher assoc-cons target f)
271 nil)
273 (defn remove-observers
274 "Remove group of observers associated with the specified watcher."
275 [watcher]
276 (.remove observers watcher)
277 nil)
279 (defn- replace-observers-watcher
280 [old-watcher new-watcher]
281 (if-let [old (.remove observers old-watcher)]
282 (.put observers new-watcher old))
283 nil)
285 (defn update
286 "Notify observers."
287 [target & args]
288 (doseq [entry observers
289 f (get (val entry) target)]
290 (apply f (key entry) target args)))
292 (defn add-context-observer
293 "Observer registered with this function will be automatically
294 removed after the next repaint is complete."
295 [target f]
296 (add-observer *scene* target f))
298 (defn repaint-on-update
299 "Trigger repaint of the current scene when the target updates."
300 [target]
301 (let [scene *scene*]
302 (if-not (identical? scene target)
303 (add-observer scene target (fn [w _] (update w))))))
305 (defn repaint
306 "Requests repaint of the current scene. If handle and state are
307 specified, the handle will be associated with the state in the
308 *states* map for the next paint iteration."
309 ([]
310 (update *scene*))
311 ([handle state]
312 (let [scene *scene*]
313 (swap! (:next-state scene) assoc handle state)
314 (update scene))))
316 ;;
317 ;; Rendering
318 ;;
320 (defn ^FontRenderContext font-context
321 "Returns FontRenderContext for the current Layer context."
322 []
323 (if (bound? (var *graphics*))
324 (.getFontRenderContext *graphics*)
325 *font-context*))
327 (defn ^AffineTransform relative-transform
328 "Returns AffineTransform: layer context -> AWT component."
329 []
330 (let [tr (.getTransform *graphics*)]
331 (.preConcatenate tr *inverse-initial-transform*)
332 tr))
334 (defn ^AffineTransform inverse-relative-transform
335 "Returns AffineTransform: AWT component -> layer context."
336 []
337 (let [tr (.getTransform *graphics*)]
338 (.invert tr) ; absolute -> layer
339 (.concatenate tr *initial-transform*) ; component -> absolute
340 tr))
342 (defn transform-point [^AffineTransform tr ^double x ^double y]
343 (let [p (Point2D$Double. x y)]
344 (.transform tr p p)
345 [(.x p) (.y p)]))
347 (defn inverse-transform-point [^AffineTransform tr ^double x ^double y]
348 (let [p (Point2D$Double. x y)]
349 (.inverseTransform tr p p)
350 [(.x p) (.y p)]))
352 ;; (defn- clip
353 ;; "Intersect clipping area with the specified shape or bounds.
354 ;; Returns new clip (Shape or nil if empty)."
355 ;; ([x y w h]
356 ;; (clip (Rectangle2D$Double. x y w h)))
357 ;; ([shape]
358 ;; (let [a1 (Area. shape)
359 ;; a2 (if (instance? Area *clip*) *clip* (Area. *clip*))]
360 ;; (.transform a1 (relative-transform))
361 ;; (.intersect a1 a2)
362 ;; (if (.isEmpty a1)
363 ;; nil
364 ;; a1))))
366 ;; Use faster clipping calculation provided by Graphics2D.
367 (defn- clip
368 "Intersect clipping area with the specified Shape in current
369 transform coordinates. Returns new clip in the AWT component
370 coordinates (Shape or nil if empty)."
371 [^Shape shape]
372 (let [^Graphics2D clip-g (.create *graphics*)]
373 (try
374 (doto clip-g
375 (.setClip shape)
376 (.setTransform *initial-transform*)
377 (.clip *clip*))
378 (if (.isEmpty (.getClipBounds clip-g))
379 nil
380 (.getClip clip-g))
381 (finally
382 (.dispose clip-g)))))
384 (defn- ^Graphics2D apply-theme
385 "Set graphics' color and font to match theme.
386 Modifies and returns the first argument."
387 ([]
388 (apply-theme *graphics* *theme*))
389 ([^Graphics2D graphics theme]
390 (doto graphics
391 (.setColor (:fore-color theme))
392 (.setFont (:font theme)))))
394 (defn- ^Graphics2D create-graphics
395 ([]
396 (apply-theme (.create *graphics*) *theme*))
397 ([^long x ^long y ^long w ^long h]
398 (apply-theme (.create *graphics* x y w h) *theme*)))
400 (defn- with-bounds-noclip*
401 [x y w h f & args]
402 (let [graphics (create-graphics)]
403 (try
404 (.translate graphics (double x) (double y))
405 (binding [*width* w
406 *height* h
407 *input-clip* (Rectangle2D$Double. 0.0 0.0 w h)
408 *graphics* graphics]
409 (apply f args))
410 (finally
411 (.dispose graphics)))))
413 (defn with-bounds*
414 [x y w h f & args]
415 (let [x (double x)
416 y (double y)
417 bounds (Rectangle2D$Double. x y w h)]
418 (when-let [clip (clip bounds)]
419 (let [^Graphics2D graphics (create-graphics)]
420 (try
421 (.clip graphics bounds)
422 (.translate graphics x y)
423 (binding [*width* w
424 *height* h
425 *clip* clip
426 *input-clip* nil
427 *graphics* graphics]
428 (apply f args))
429 (finally
430 (.dispose graphics)))))))
432 (defmacro with-bounds
433 [x y w h & body]
434 `(with-bounds* ~x ~y ~w ~h (fn [] ~@body)))
436 (defmacro with-theme
437 [theme & body]
438 `(binding [*theme* (merge *theme* ~theme)]
439 ~@body))
441 (defmacro with-color
442 [color-or-keyword & body]
443 (let [color-form (if (keyword? color-or-keyword)
444 `(~color-or-keyword *theme*)
445 color-or-keyword)]
446 `(let [color# ~color-form
447 g# *graphics*
448 old-color# (.getColor g#)]
449 (try
450 (.setColor g# color#)
451 ~@body
452 (finally
453 (.setColor g# old-color#))))))
455 (defmacro with-stroke [stroke & body]
456 `(let [g# *graphics*
457 old-stroke# (.getStroke g#)]
458 (try
459 (.setStroke g# ~stroke)
460 ~@body
461 (finally
462 (.setStroke g# old-stroke#)))))
464 (defmacro with-hints
465 [hints & body]
466 `(let [h# ~hints
467 g# *graphics*
468 old# (.getRenderingHints g#)]
469 (try
470 (.addRenderingHints g# h#)
471 ~@body
472 (finally
473 (.setRenderingHints g# old#)))))
475 (defn with-hints* [hints f & args]
476 (with-hints hints
477 (apply f args)))
479 ;; TODO: constructor for AffineTransform.
480 ;; (transform :scale 0.3 0.5
481 ;; :translate 5 10
482 ;; :rotate (/ Math/PI 2))
484 (defmacro with-transform [transform & body]
485 `(let [g# *graphics*
486 old-t# (.getTransform g#)]
487 (try
488 (.transform g# ~transform)
489 ~@body
490 (finally
491 (.setTransform g# old-t#)))))
493 (defmacro with-rotate [theta ax ay & body]
494 `(let [transform# (AffineTransform/getRotateInstance ~theta ~ax ~ay)]
495 (with-transform transform# ~@body)))
497 (defmacro with-translate [x y & body]
498 `(let [x# ~x
499 y# ~y
500 g# *graphics*]
501 (try
502 (.translate g# x# y#)
503 ~@body
504 (finally
505 (.translate g# (- x#) (- y#))))))
507 (defn draw!
508 "Draws layer."
509 ([layer]
510 (let [graphics (create-graphics)]
511 (try
512 (binding [*graphics* graphics]
513 (render! layer))
514 (finally
515 (.dispose graphics)))))
516 ([layer x y]
517 (draw! layer x y true))
518 ([layer x y clip?]
519 (let [geom (geometry layer)]
520 (draw! layer x y (width geom) (height geom) clip?)))
521 ([layer x y width height]
522 (draw! layer x y width height true))
523 ([layer x y width height clip?]
524 (if clip?
525 (with-bounds* x y width height render! layer)
526 (with-bounds-noclip* x y width height render! layer))))
528 (defn draw-aligned!
529 "Draws layer. Location is relative to the layer's anchor point for
530 the specified alignment."
531 ([layer h-align v-align x y]
532 (let [geom (geometry layer)
533 w (width geom)
534 h (height geom)]
535 (draw! layer
536 (- x (anchor-x geom h-align w))
537 (- y (anchor-y geom v-align h))
538 w h)))
539 ([layer h-align v-align x y w h]
540 (let [geom (geometry layer)]
541 (draw! layer
542 (- x (anchor-x geom h-align w))
543 (- y (anchor-y geom v-align h))
544 w h))))
546 ;;
547 ;; Event handling.
548 ;;
550 (defn with-handlers*
551 [handle handlers f & args]
552 (binding [*event-dispatcher* (create-dispatcher
553 *event-dispatcher* handle handlers)]
554 (apply f args)))
556 (defmacro with-handlers
557 "specs => (:event-id name & handler-body)*
559 Execute form with the specified event handlers."
560 [handle form & specs]
561 `(with-handlers* ~handle
562 ~(reduce (fn [m spec]
563 (assoc m (first spec)
564 `(fn [~(second spec)]
565 ~@(nnext spec)))) {}
566 specs)
567 (fn [] ~form)))
569 (defn picked? [handle]
570 (handle-picked? *event-dispatcher* handle))
572 (defn hovered? [handle]
573 (handle-hovered? *event-dispatcher* handle))
575 ;;
576 ;; EventDispatcher implementation
577 ;;
579 (def awt-events
580 {java.awt.event.MouseEvent/MOUSE_CLICKED :mouse-clicked
581 java.awt.event.MouseEvent/MOUSE_DRAGGED :mouse-dragged
582 java.awt.event.MouseEvent/MOUSE_ENTERED :mouse-entered
583 java.awt.event.MouseEvent/MOUSE_EXITED :mouse-exited
584 java.awt.event.MouseEvent/MOUSE_MOVED :mouse-moved
585 java.awt.event.MouseEvent/MOUSE_PRESSED :mouse-pressed
586 java.awt.event.MouseEvent/MOUSE_RELEASED :mouse-released
587 java.awt.event.MouseEvent/MOUSE_WHEEL :mouse-wheel})
589 (def dummy-event-dispatcher
590 (reify EventDispatcher
591 (listen! [_ _])
592 (create-dispatcher [this _ _] this)
593 (commit [_])
594 (handle-picked? [_ _])
595 (handle-hovered? [_ _])))
597 ;; Not using defrecord to avoid unacceptable overhead of recursive
598 ;; hash code calculation.
599 (deftype DispatcherNode [handle handlers parent
600 ^Shape clip ^AffineTransform transform
601 bindings]
602 EventDispatcher
603 (listen! [this component]
604 (listen! parent component))
605 (create-dispatcher [this handle handlers]
606 (create-dispatcher parent handle handlers))
607 (commit [this]
608 (commit parent))
609 (handle-picked? [this handle]
610 (handle-picked? parent handle))
611 (handle-hovered? [this handle]
612 (handle-hovered? parent handle)))
614 (defn- make-node [handle handlers]
615 (let [clip (if *input-clip*
616 (clip *input-clip*)
617 *clip*)
618 bindings (-> (get-thread-bindings)
619 (dissoc (var *graphics*))
620 (assoc (var *font-context*) (font-context)))]
621 (DispatcherNode. handle handlers *event-dispatcher* clip
622 (relative-transform)
623 bindings)))
625 (defn- add-node [tree ^DispatcherNode node]
626 (assoc-cons tree (.parent node) node))
628 (defn- nodes [tree]
629 (apply concat (vals tree)))
631 (defn- under-cursor
632 "Returns a vector of child nodes under cursor."
633 [node tree ^long x ^long y]
634 (some (fn [^DispatcherNode n]
635 (if (and (.clip n) (.contains ^Shape (.clip n) x y))
636 (conj (vec (under-cursor n tree x y)) n)))
637 (get tree node)))
639 (defn- translate-mouse-event [^java.awt.event.MouseEvent event
640 ^AffineTransform tr id]
641 (let [[x y] (inverse-transform-point tr (.getX event) (.getY event))
642 rotation (if (instance? MouseWheelEvent event)
643 (.getWheelRotation ^MouseWheelEvent event)
644 nil)]
645 (->MouseEvent id (.getWhen event) x y
646 (.getXOnScreen event) (.getYOnScreen event)
647 (.getButton event)
648 rotation
649 tr
650 (.getComponent event))))
652 (defn- translate-and-dispatch
653 ([nodes first-only ^java.awt.event.MouseEvent event]
654 (translate-and-dispatch nodes first-only
655 event (awt-events (.getID event))))
656 ([nodes first-only event id]
657 (if-let [^DispatcherNode node (first nodes)]
658 (let [handlers (.handlers node)
659 handler (get handlers id)]
660 (if handler
661 (do
662 (with-bindings* (.bindings node)
663 handler
664 (translate-mouse-event event (.transform node) id))
665 (when-not first-only
666 (recur (rest nodes) false event id)))
667 (when-not (and (= id :mouse-dragged)
668 (or (contains? handlers :mouse-pressed)
669 (contains? handlers :mouse-released)))
670 (recur (rest nodes) first-only event id)))))))
672 (defn- process-mouse-event
673 [dispatcher ^java.awt.event.MouseEvent source-event]
674 (let [{active-ref :active
675 hovered-ref :hovered
676 picked-ref :picked
677 last-ref :last-motion
678 tree-ref :tree} dispatcher
679 pressed (and source-event
680 (== (.getID source-event)
681 java.awt.event.MouseEvent/MOUSE_PRESSED))
682 released (and source-event
683 (== (.getID source-event)
684 java.awt.event.MouseEvent/MOUSE_RELEASED))
685 ^java.awt.event.MouseEvent last-event @last-ref
686 ^java.awt.event.MouseEvent event (or source-event last-event)]
687 (when event
688 (let [x (.getX event)
689 y (.getY event)
690 active @active-ref
691 active (if (and active
692 source-event
693 (== (.getX last-event) x)
694 (== (.getY last-event) y))
695 active
696 (ref-set active-ref
697 (under-cursor dispatcher @tree-ref x y)))
698 acted (cond
699 pressed (ref-set picked-ref active)
700 released (let [picked @picked-ref]
701 (ref-set picked-ref nil)
702 picked)
703 :else active)
704 picked (seq @picked-ref)
705 pred #(= (.handle ^DispatcherNode %1) (.handle ^DispatcherNode %2))
706 hovered (if picked
707 (filter #(some (partial pred %) picked) active)
708 active)
709 remove-all (fn [c1 c2]
710 (filter #(not (some (partial pred %) c2)) c1))
711 old-hovered @hovered-ref
712 exited (remove-all old-hovered hovered)
713 entered (remove-all hovered old-hovered)
714 moved (or picked (remove-all hovered entered))]
715 (ref-set hovered-ref hovered)
716 (ref-set last-ref event)
717 [exited entered moved acted event]))))
719 (defn- dispatch-mouse-event
720 [dispatcher source-event button?]
721 (when-let [[exited
722 entered
723 moved
724 acted
725 event] (dosync (process-mouse-event dispatcher source-event))]
726 (when button?
727 (translate-and-dispatch acted true event))
728 (translate-and-dispatch exited false event :mouse-exited)
729 (translate-and-dispatch entered false event :mouse-entered)
730 (when-not button?
731 (translate-and-dispatch moved true source-event))))
733 (defrecord RootEventDispatcher [tree-r ;; register
734 tree ;; dispatch
735 active ;; nodes under cursor
736 hovered ;; mouse entered
737 picked ;; mouse pressed
738 last-motion]
739 EventDispatcher
740 (listen! [dispatcher component]
741 (doto ^Component component
742 (.addMouseListener dispatcher)
743 (.addMouseWheelListener dispatcher)
744 (.addMouseMotionListener dispatcher)))
745 (create-dispatcher [dispatcher handle handlers]
746 (let [node (make-node handle handlers)]
747 (dosync (alter tree-r add-node node))
748 node))
749 (commit [dispatcher]
750 (let [[exited
751 entered
752 _ _
753 event] (dosync
754 ;; TODO: retain contexts that do
755 ;; not intersect graphics
756 ;; clipping area in tree.
757 (ref-set tree @tree-r)
758 (ref-set tree-r {})
759 (process-mouse-event dispatcher nil))]
760 ;; Send mouse entered and exited events if necessary due to
761 ;; updated layout.
762 (translate-and-dispatch exited false event :mouse-exited)
763 (translate-and-dispatch entered false event :mouse-entered)))
764 (handle-picked? [dispatcher handle]
765 (some #(= handle (.handle ^DispatcherNode %)) @picked))
766 (handle-hovered? [dispatcher handle]
767 (some #(= handle (.handle ^DispatcherNode %)) @hovered))
768 MouseListener
769 (mouseEntered [dispatcher event]
770 (dispatch-mouse-event dispatcher event false))
771 (mouseExited [dispatcher event]
772 (dispatch-mouse-event dispatcher event false))
773 (mouseClicked [dispatcher event]
774 (dispatch-mouse-event dispatcher event true))
775 (mousePressed [dispatcher event]
776 (dispatch-mouse-event dispatcher event true))
777 (mouseReleased [dispatcher event]
778 (dispatch-mouse-event dispatcher event true))
779 MouseWheelListener
780 (mouseWheelMoved [dispatcher event]
781 (dispatch-mouse-event dispatcher event true))
782 MouseMotionListener
783 (mouseDragged [dispatcher event]
784 (dispatch-mouse-event dispatcher event false))
785 (mouseMoved [dispatcher event]
786 (dispatch-mouse-event dispatcher event false)))
788 (defn root-event-dispatcher []
789 (->RootEventDispatcher
790 (ref {}) (ref {}) ;; trees
791 (ref nil) (ref nil) (ref nil) ;; node states
792 (ref nil))) ;; last event
794 ;;
795 ;; Scene
796 ;;
798 (defrecord Scene [layer
799 event-dispatcher
800 component
801 rendering-hints
802 next-state])
804 ;; Define rendering hints that affect font metrics to make sure that
805 ;; Graphics and Scene FontRenderContexts are consistent.
806 (def ^:private default-rendering-hints
807 {RenderingHints/KEY_TEXT_ANTIALIASING
808 RenderingHints/VALUE_TEXT_ANTIALIAS_DEFAULT,
809 RenderingHints/KEY_FRACTIONALMETRICS
810 RenderingHints/VALUE_FRACTIONALMETRICS_DEFAULT})
812 (defn make-scene
813 ([layer]
814 (make-scene layer dummy-event-dispatcher nil))
815 ([layer event-dispatcher]
816 (make-scene layer event-dispatcher nil))
817 ([layer event-dispatcher ^Component component]
818 (make-scene layer event-dispatcher component nil))
819 ([layer event-dispatcher ^Component component hints]
820 (let [hints (merge default-rendering-hints hints)]
821 (->Scene layer
822 event-dispatcher
823 component
824 hints
825 (atom nil)))))
827 (defn- get-and-set!
828 "Atomically sets the value of atom to newval and returns the old
829 value."
830 [atom newval]
831 (loop [v @atom]
832 (if (compare-and-set! atom v newval)
833 v
834 (recur @atom))))
836 (defn draw-scene!
837 [scene ^Graphics2D graphics width height]
838 (.addRenderingHints graphics (:rendering-hints scene))
839 (binding [*states* (get-and-set! (:next-state scene) nil)
840 *scene* scene
841 *graphics* graphics
842 *initial-transform* (.getTransform graphics)
843 *inverse-initial-transform* (-> graphics
844 .getTransform
845 .createInverse)
846 *event-dispatcher* (:event-dispatcher scene)
847 *width* width
848 *height* height
849 *clip* (Rectangle2D$Double. 0.0 0.0 width height)
850 *input-clip* nil
851 *time* (System/nanoTime)]
852 (apply-theme)
853 (let [tmp-watcher (Object.)]
854 ;; Keep current context observers until the rendering is
855 ;; complete. Some observers may be invoked twice if they
856 ;; appear in both groups until tmp-watcher is removed.
857 (replace-observers-watcher scene tmp-watcher)
858 (try
859 (render! (:layer scene))
860 (finally
861 (remove-observers tmp-watcher)
862 (commit (:event-dispatcher scene)))))))
864 (defn- scene-font-context [scene]
865 (let [hints (:rendering-hints scene)
866 ^Component c (:component scene)
867 t (if c (->> c
868 .getFont
869 (.getFontMetrics c)
870 .getFontRenderContext
871 .getTransform))]
872 (FontRenderContext.
873 t
874 (get hints RenderingHints/KEY_TEXT_ANTIALIASING)
875 (get hints RenderingHints/KEY_FRACTIONALMETRICS))))
877 (defn scene-geometry [scene]
878 (binding [*scene* scene
879 *font-context* (scene-font-context scene)]
880 (geometry (:layer scene))))
882 (defn set-cursor! [^Cursor cursor]
883 (when-let [^Component component (:component *scene*)]
884 (EventQueue/invokeLater #(.setCursor component cursor))))